what filters do YOU use for DV => DVD?

[ou8thisSN]

So, i've spent a few days on this forum learning the ins and outs of DV processing and Avisynth etc. But the output isnt as great as I had hoped it would be. I dont know if its becuase I am expecting too much from my 1-CCD Digital8 sony camcorder or what, but I was wondering what filters if any you guys are using that I should try out or gives very good results.

Because I dont know anything, I have used the Doom9 DV => DVD guide for CCE and that guide recommends Convolution3d and ReInterpolate411.

one of the big problems is that the video is noisy/grainy (but even the source is like that... is it supposed to be?)

and the other problem is that during pans... you can see what i call Ghosting... i mean you can see vertical lines trailing as the camera pans. its quite distracting and NOT present in the uncompressed AVi file.

All I did was take the direct stream in Vdub at 29.97 and encode with CCE following the procedure in the guide...

[communist]

I dont know if its becuase I am expecting too much from my 1-CCD Digital8 sony camcorder
Could be.

one of the big problems is that the video is noisy/grainy (but even the source is like that... is it supposed to be?)
You can fix noise / grain to some degree but it will also sort of flatten your image. Next time you shoot something try opening the Iris up until details get crushed (blown up white) and make sure lighting is ok. Also try not to use Gain - though it will brighten up things it will also add more grain / noise to the image.

and the other problem is that during pans... you can see what i call Ghosting... i mean you can see vertical lines trailing as the camera pans. its quite distracting and NOT present in the uncompressed AVi file.
Your original file is not uncompressed (unless you resaved it as uncompressed). Its DV-compressed. What you're describing sounds like interlacing - it is most certainly present in your source aswell (unless your camcorder can record progressive). It could also be deinterlacing artifacts if you're using an deinterlacer. You wont notice those lines on TV. Also if you encode your file with CCE make sure you encode it as interlaced otherwise no on-the-fly deinterlacing will be applied by your PC Software DVD-Player -> resulting in those lines.

For explanations on interlacing and what you can do about it etc have a look here: http://www.100fps.com/

[ou8thisSN]

so are you saying the plethora of discussions here regarding newer filters are not for my situtation, because my computer is just giving me what i started with and using anything else will not really make it better but worse?

who needs/uses RemoveGrain or RemoveDirt?

[communist]

Yeah more or less thats what I said. But some filters can *improve* image quality. And with *improve* I mean change it either to your or someone else's liking. Denoisers are a good example: Some people prefer to have their encodes as close to the source as possible when doing DVD backups (as long as the DVDs dont look like crap to begin with) - and that often means preserving filme noise / grain. Others can take a light denoising if it increases compressibility etc.
You'll have to see for yourself what works *best*.

Since I havent seen your footage which shows the problems you describe I cant comment on what filter could improve it (not that I could recommend a lot... my AviSynth knowledge is rather limited ;-).

There is no all-in-one script (and or filter) for every kind of footage yet and there will never be ;)

[Piper]

There is no all-in-one script (and or filter) for every kind of footage yet and there will never be ;)

This is good advice.

I've been experimenting with RemoveDirt on some my own DV sources lately as I personally find the grainy noise from my DV camea quite irritating. The trouble with this kind of footage is that there's often a lot of shaky camera motion and if too much filtering is applied, you run the risk of smearing the image or producing other undesirable results. I'd recommend experimenting with a variety of different denoisers to help determine what you find most pleasing to the eye.

[ou8thisSN]

okay, i followed a lot of your advice and decided to leave well enough alone. I wont be using any filters besides the ones i already have been using and the results are just fine... its as good as the output on the camcorder, and thats really what i am worried about.

in any case, i think the main problem is that my camcorder itself the bottleneck... you cant squeeze out a DVD quality production just because your 1-ccd camcorder is "digital". Oh well, i'm happy with what we got now, and am counting the days to HD-Cams...

[FredThompson]

There is a lot of bad advice about video encoding. The all-too-common misconception that deinterlacing is a good thing to do creates lots of problems for people.

I've been working with NTSC DV camcorder source for years.

If I must make deinterlaced output (MPEG1 for PowerPoint) I open the stream with VirtualDub and set the following filters:

chroma smoother

Donald Graft's Smart Deinterlacer 2.8 beta 1 set for frame-and-field differencing, Edge-directed interpolate, motion map denoising, motion threshold of 10

Shadow Smoother (sometimes, be careful with this)

Smart Smoother Hi-Quality (sometimes, be careful with this)

--

For interlaced output, I use this AviSynth script. Note it includes frame numbering which is for pre-production use here.

AVISource("DV Tape.avi")

#
# PeachSmoother - Noise Removal
# http://www.avisynth.org/users/warpenterprises/
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\PeachSmoother.dll")
#
# ReInterpolate411 - Pseudo conversion of 4:1:1 => 4:2:2
# http://home.comcast.net/~trbarry/
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\ReInterpolate411.dll")
#
##########################
#
# Enforce CCIR-601 (luma=16-236 and chroma=16-240)
#
Limiter(min_luma=16)
#
##########################

##########################
#
# Convert 4:1:1->4:2:2 for NTSC DV
#
ReInterpolate411()
#
##########################

##########################
#
# Ensure file is top field first
#
GetParity() ? nop() : DoubleWeave().SelectOdd()
#
##########################

##########################
#
PeachSmoother()
#
##########################

##########################
#
# Frame number overlay
#
vid00=last
BlankClip(vid00,width=70,height=58,color=$000000)
SeparateFields()
AssumeTFF()
SelectEven()
vid01=ShowFrameNumber()
Layer(vid00,vid01,"add",x=10,y=441,use_chroma=true)
#
##########################
I use the MainConcept DV codec. Lots of people swear by the old Panasonic or Sony codecs. However, there is yet to be any definitive proof that those old codecs give "better" output. All you'll probably find is personal opinions based on the smoothness of the output of homemade test samples. Smoothness does not indicate correctness of a codec process, it can indicate an incorrect process.

Be sure you are using the same color range in the codec which your camcorder uses. If your camcorder uses the CCIR-601 range and your codec is expanding to the full possible range, or vice versa, you will get altered output.

If at all possible, set your camcorders white balance before each shot. Mercury vapor and other industrial lighting can play havoc with a consumer camcorder.

Be careful with noise reduction. Any "removal" of noise is based on guesswork. Some noise reduction methods are better than others.

If you would like me to look at a sample of your source, burn some to DVDR and send me a PM for my address. You'll need to do this ASAP. I leave for Europe (yes, with camcorders and cameras) in a week. There is still time to look over what you have but very little time to delay.

[Wilbert]

I don't want to nickpick, but ReInterpolate411() doesn't convert 411 to 422 :)

I guess you know what it does, but for other people: It just interpolates the chroma horizontally (which was originally duplicated by the DV codec).

[FredThompson]

Yeah, I know that. I claim to be the squeaky wheel who goaded Tom into writing it. I've changed the comments for clarity.

Now let's see how long it is before someone points out I didn't set the call for cnr2...

'cause I'm lazy.

[ou8thisSN]

well i am certainly not in the same league as most of you, nor do i have any professional equipment or even prosumer camcorders that necessitate all the filters, settings you talked about. It is a Sony DCR-TRV103NTSC it was the first generation Digital8 camcorders with a dirty lens (that we never cleaned and i realize now based on the output) and a 1-CCD imager.

Based on my current script, I am quite satisfied with the results. It looks exactly like it did on the camcorder, and my folks are very happy, so I dont think i need to send you a sample but thanks for your gracious offer to look at it.

Might try your script though... if its not too much work for me or things to change. we'll see. Keep in mind my experience to all this is only 6 days, and I frankly dont know anything about what functions and filters are doing, just using what i saw in the guide.

[FredThompson]

The script is really very simple.

Limiter enforces the "legal" range for TV brightness and color. Think of it as a way of ensuring detail is not clipped in the real bright and real dark parts.

ReInterpolate411 helps reduce unwanted artifacts such as those shown here: http://www.geocities.com/xesdeeni2001/411Comparison-9x.PNG NTSC DV uses one color value for a horizontal rectangle of four pixels. If you don't use it, your encode is really the least common demoninator. Use it and you'll get a nicer image.

DV video has the bottom field first in a frame and almost everything else is top field first so I flip it.

Peach is a basic cleaner which adjusts itself to the source material. You get a somewhat "cleaner" image and better use space when you encode.

CNR2 and Greyscale aren't used currently. They're left over from when I was doing VHS captures through DV. I get better results with high bitrate MPEG2 capture. Actually, you can ignore this comment. I'll remove them from the script right now so it's less cluttered.

Put # at the start of each line in the frame numbering section to disable that. It inserts a frame number which is real helpful for me in discussing with other people where things are supposed to be edited. I left it in because it's clever. Someone here gave that stuff many moons ago.

You might also be interested in this thread which discusses averaging the brightness. It's pretty handy for some camcorder stuff given most people don't have pro light kits set up. http://forum.doom9.org/showthread.php?threadid=94429

[ou8thisSN]

okay... well just for reference, here is my current script. I definitely want to keep the letterbox command. so should i just have the separatefields and letterboxcommands before your script addition? what about convolution3d?

AviSource("E:\SWD_tape1\CCE Product\ActualTest.avi")
Letterbox(60,60)
SeparateFields()
ConverttoYUY2()
ReInterpolate411()
odd=SelectOdd.Convolution3D(1, 6, 10, 6, 8, 2.8, 0)
evn=SelectEven.Convolution3D(1, 6, 10, 6, 8, 2.8, 0)
Interleave(evn,odd)
Weave()
DoubleWeave.SelectOdd()


also you said: Limiter enforces the "legal" range for TV brightness and color. Think of it as a way of ensuring detail is not clipped in the real bright and real dark parts.


my tvs are HDTVs, do they use the same legal range for brightness/color? or does that not matter because my DVD-R discs are NTSC therefore dictate that i use those standards....

[FredThompson]

Why do you want Letterbox? All it does is turn the overscan areas into black but your camcorder uses the full frame for video. Your HDTV should be able to show that extra area. Is this something you're doing because of the aspect ratio of your TVs? If that's the case, perhaps your camcorder supports a widescreen mode. If you're going to use it, Try to stick with values which are a multiple of 16, if at all possible. There's a technical reason which involves how MPEG2 is encoded. If you change those values to 64 you'll get a little better result.



Your script does basically the same thing as mine, ReInterpolate and some noise removal. Peach does just about everything I'd like a denoiser to do. It doesn't scrub too hard, it adjusts itself and it's easy to use. I do have some other denoisers in my machines but rarely use anything else for camcorder source. There is a temptation to be too heavy-handed with denoising at first. All denoising involves guess work so use it sparingly. Some people really like Convolution3D. They both take about the same amount of time for processing and both do spatial denoising and temporal denoising.

WRT the chroma and luma range, it's a function of your camcorder, not the display device. The vast, vast majority of consumer camcorders use the smaller range. Some filters, supposedly, will not perform properly on values outside that range. In any event, if that's the source range, you really should keep it. If you have source with the limited range then stretch it to fill all possible values, you'll lose detail if any part of the process clips the values and you'll also alter the character of the video. To oversimplify, you can end up "flattening" parts of the image at the low and high ends unintentionally.

Come to think of it, really paranoid types would probably use multiple instances of that function throughout their script. I know my camcorder uses the restricted range so it's in the script for source tapes which come from other people. The more I think about it, it's probably not that critical. It's probably more important that you have your DV codec set to return only the limited range if that is what comes from your camcorder. IIRC, a Sony or Canopus codec returns the full range. I've been trying to remember how to test a camcorder for the range and don't remember how I did it.

CCE isn't that great for interlaced source. You might want to try ProCoder or HC which is at: http://forum.doom9.org/showthread.php?threadid=93211

If you're happy with your script, stick with it. There are quite a few different ways to reach the same goal.

Oh, I forgot to explain why I bother to flip the field dominance. It's not that uncommon for me to combine DV with other video sources. If the field dominance flips around, it confuses some encoders and playback devices. It's just a habit of mine to "correct" the dominance of DV so everything will match properly.

[ou8thisSN]

okay, so if our scripts are essentially the same, i have 3 questions:

does the Peach filter do a better job of denoising DV NTSC 1-CCD camcorder sources than convolution?

how do i figure out what the luna or WRT range of my camcorder is? you said "YOU KNOW your camcorder's range", but you dont know how i should find out... in that case should i still limit the range used by your script?

Do i need to worry about Field dominance? As I said, I'm not doing anything fancy like you... so, shouldnt matter right?


finally: if you do agree that I need to add peach and WRT range filters to my script... can you tell me where it needs to go? Below, i have provided what I figured was a way of integrating your script into mine, but since I dont really know what i'm doing, i'd appreciate your glace over.

AviSource("E:\SWD_tape1\CCE Product\ActualTest.avi")
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\PeachSmoother.dll")
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\ReInterpolate411.dll")
Letterbox(64,64)
SeparateFields()
Limiter(min_luma=16)
ConverttoYUY2()
ReInterpolate411()
GetParity() ? nop() : DoubleWeave().SelectOdd()
PeachSmoother()




Also, the reason I use the Letterbox command is because when everything was shot, it was shot in 4:3. I have since set the mode to 16:9 but the stupid camcorder forgets everytime its left unplugged for a while and you have to reset it to 16:9 mode, and it disables steadshot when you do label it.... wtf? anyway, the reason i'm encoding in letterbox is because like i said, our TVs are 16:9, and displaying 4:3 either with the grey bars, or stretched looks awful. And because most home movies are filled with pans, the distortion from the non-linear stretch of most 16:9 tvs would make it absolutely distracting. So we can live with the crop and letterboxing.

[FredThompson]

WRT = "with regards to" :) It's a lazy way of typing less.

I've been trying to remember how I determined the range of my camcorder. It was a manual process which involved some source from the camcorder and multiple instances of VirtualDub and different DV decoding ranges. A couple of years ago some email showed up from someone who wanted help denoising some really tough DV. It was a stage shot with smoke and the white end was over saturated. It's a lot easier to do that kind of correction now with some of the recent filters that will let you scale things non-linearly. Anyhoo, we were looking at various codecs and that's when we found the Sony was forced to the full range and we also figured out a way to test the range of a camcorder based on some source from it. Believe me, I'd explain how if I remembered. Those emails are long gone in a drive crash. Let me think about this some more. It was a simple process but not obvious.

Hmm...well. I have an idea but it will require some work. M$ published a spec for DV in the AVI format. Maybe shooting a short segment with the lens cap on and covered with a towel of something to prevent light leaks would give an accurate black end recording. It just might be possible to test the extracted AVI file for data values. That might actually be the most reliable method because it avoids any codecs. Let me think about this some more. I really do want to tell you how to do this. Maybe a few knocks to my head will jar something loose.

You might want to consider buying a lens to shoot in 16:9. http://www.adorama.com/ has a good supply of stuff and reasonable prices. A UV filter is a "must". It will protect the lens and help reduce glare. I also use a circular polarized filter and/or a neutral density filter. WRT widescreen, there's a lot of good infromation here: http://www.geocities.com/aussie01au/ You might find you prefer to keep the whole process widescreen.

I can't say Peach is better than Convolution3D. That's something you'll have to decide for yourself. Peach works with interlaced source so the scripts are slightly less complex. If you're not mixing source, don't worry about field dominance. Just make sure your encoder knows the proper dominance before it works. Try setting it improperly once and you'll see why :)

AviSource("E:\SWD_tape1\CCE Product\ActualTest.avi")
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\PeachSmoother.dll")
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\ReInterpolate411.dll")
Letterbox(64,64)
Limiter(min_luma=16)
ReInterpolate411()
PeachSmoother()The brightness averaging thread I pointed you to is helpful for home camcorder stuff. So is this: http://forum.doom9.org/showthread.php?s=&threadid=74003 Save those for later when you're more comfortable with the process. There are also some very nice filters for adjusting color balance such as http://www.trevlac.us/colorCorrection/colorTools.html (Ahem! Trevlac, are you reading this?!?!)

[troy]

I never really got good results with c3d and dv sources. It seems to not be tailor made for dv sources. Peachsmoother seems to work better. If you have the computer time you should try iip. It really seems to do wonders for my dv sources. Of course it takes about 5 days for a 2 hour video on my slow computer but it really is something to see when it is done.

[FredThompson]

Here's what I'm using now. It is not a simple filter chain, you'll need to enable lines and set some values. I like this layout because the vast majority of stuff I want is included. The noise removal comes from Ivo with results better than PeachSmoother.

General Cleanup.avs##########################
#
# General Cleanup Script
#
# 2005-06-21 01:05:00
#
##########################

##########################
#
# Load filters
#
# ChromaShift - Move Chroma
# http://www.geocities.com/siwalters_uk/chromashift.html
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\ChromaShift.dll")
#
# CNR2 - chroma filter
# http://ziquash.chez.tiscali.fr/
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\Cnr2.dll")
#
# Descratch - Film Scratch Removal
# http://bag.hotmail.ru/descratch/descratch.dhtml
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\Descratch.dll")
#
# InterlacedScale - Resize Interlaced Frames
# http://forum.doom9.org/showthread.php?s=&threadid=74906
#
# KernelDeint - Deinterlace
# http://neuron2.net/kerneldeint/kerneldeint.html
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\KernelDeint.dll")
#
# ReInterpolate411 - Pseudo conversion of 4:1:1 => 4:2:2
# http://home.comcast.net/~trbarry/
#
LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\ReInterpolate411.dll")
#
# RemoveDirtS - Cleaner
# http://www.removedirt.de.tf/
#
Import("C:\Program Files\AviSynth 2.5\plugins\VirtualDubMod Crashers\RemovedirtS.avs")
#
# WhiteBalance - Adjusts white balance when fed a "white" value
# http://forum.doom9.org/showthread.php?t=96169
#
Import("C:\Program Files\AviSynth 2.5\plugins\WhiteBalance.avs")
#
##########################

##########################
#
# Load file
#
# AVISource("DV Tape.avi")
# DirectShowSource("file.avi")
# MPEG2Source("project.d2v")
#
##########################

##########################
#
# Make NTSC DV "play nice"
#
# ReInterpolate411()
#
##########################

##########################
#
# Ensure file is top field first
#
GetParity() ? nop() : DoubleWeave().SelectOdd()
#
##########################

##########################
#
# GreyScale()
#
##########################

##########################
#
# Repair chroma
#
# CNR2()
#
# ChromaShift(c=-2,l=-2)
#
##########################

##########################
#
# Interlaced frames
#
# Fill Dropouts
#
# ConvertToYV12()
# AssumeTFF().SeparateFields()
# TurnLeft()
# Descratch(modey=0,modeu=3,modev=3,mindif=1,minlen=50,maxgap=20,blurlen=50,
# keep=100,mark=false,border=0,maxangle=0)
# TurnRight()
#
# Clean (2 versions)
#
# odd=SelectOdd.removedirt(repmode=17)
# evn=SelectEven.removedirt(repmode=17)
# Interleave(evn,odd)
# Weave()
#
# odd=SelectOdd.removedirt(repmode=17).UnsharpMask(strength=30, radius=3, threshold=10)
# evn=SelectEven.removedirt(repmode=17).UnsharpMask(strength=30, radius=3, threshold=10)
# Interleave(evn,odd)
# Weave()
#
# Resize
#
# InterlacedScale(480,480,5,1)
# InterlacedScale(480,576,5,1)
# InterlacedScale(720,480,5,1)
# InterlacedScale(720,576,5,1)
#
##########################

##########################
#
# Deinterlace
#
# KernelDeint(order=1,sharp=true,threshold=2)
#
##########################

##########################
#
# Progressive Frames
#
# Fill Dropouts
#
# ConvertToYV12()
# TurnLeft()
# Descratch(modey=0,modeu=3,modev=3,mindif=1,minlen=50,maxgap=20,blurlen=50,
# keep=100,mark=false,border=0,maxangle=0)
# TurnRight()
#
# Clean (2 versions)
#
# RemoveDirt(repmode=17)
#
# RemoveDirt(repmode=17).UnsharpMask(strength=30, radius=3, threshold=10)
#
# Resize
#
# BilinearResize(480,480)
# BilinearResize(480,576)
# Lanczos4Resize(720,480)
# Lanczos4Resize(720,576)
#
##########################

##########################
#
# PAL -> Film FPS
#
# AssumeFPS(24,true)
#
##########################

##########################
#
# WhiteBalance
#
# r,g,b: the int values of the RGB channels of a pixel that should be white
# bright: a brightness modifier, below 1 reduces, above 1 increases, 1 no effect.
# level: how much effect, 0 no effect, 1 full effect
#
# ConvertToRGB32()
# WhiteBalance(int r, int g, int b, float bright, float level)
#
##########################

##########################
#
# Frame number overlay
#
# vid00=last
# BlankClip(vid00,width=70,height=58,color=$000000)
# SeparateFields()
# AssumeTFF()
# SelectEven()
# vid01=ShowFrameNumber()
# Layer(vid00,vid01,"add",x=10,y=441,use_chroma=true)
#
##########################RemoveDirtS.avs##########################
#
# RemoveDirt Script
#
# 2005-06-21 01:05:00
#
##########################

##########################
#
# Load filters
#
# RemoveDirt - Cleaner
# http://www.removedirt.de.tf/
#
# RemoveGrain - Cleaner
# http://www.removegrain.de.tf/

LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\VirtualDubMod Crashers\RemoveGrainS.dll")

LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\VirtualDubMod Crashers\RemoveDirtS.dll")

LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\VirtualDubMod Crashers\RepairS.dll")

LoadPlugin("C:\Program Files\AviSynth 2.5\plugins\VirtualDubMod Crashers\SSEToolsS.dll")

function RemoveDirtS(clip input, bool "_grey", int "repmode")
{
_grey=default(_grey, false)
repmode=default(repmode, 16)
clmode=17
clensed=Clense(input, grey=_grey, cache=4)
sbegin = ForwardClense(input, grey=_grey, cache=-1)
send = BackwardClense(input, grey=_grey, cache=-1)
alt=Repair(SCSelect(input, sbegin, send, clensed, debug=true), input, mode=repmode, modeU = _grey ? -1 : repmode )
restore=Repair(clensed, input, mode=repmode, modeU = _grey ? -1 : repmode)
corrected=RestoreMotionBlocks(clensed, restore, neighbour=input, alternative=alt, gmthreshold=70, dist=1, dmode=2, debug=false, noise=10, noisy=12, grey=_grey)
return RemoveGrain(corrected, mode=clmode, modeU = _grey ? -1 : clmode )
}
WhiteBalance.avsfunction WhiteBalance(clip clip, int r, int g, int b, float bright, float level)
{
largest = ((r > g) ? (r) : (g))
largest = ((largest > b) ? (largest) : (b))
largest = largest * bright
new_r = gradient(1,(largest / Float(r)),level)
new_g = gradient(1,(largest / Float(g)),level)
new_b = gradient(1,(largest / Float(b)),level)
return clip.RGBAdjust(new_r,new_g,new_b,1)

function gradient(float low, float high, float point)
{
return ((high - low) * point) + low
}
}

[ou8thisSN]

I never really got good results with c3d and dv sources. It seems to not be tailor made for dv sources. Peachsmoother seems to work better. If you have the computer time you should try iip. It really seems to do wonders for my dv sources. Of course it takes about 5 days for a 2 hour video on my slow computer but it really is something to see when it is done.


5 days! good lord! wtf... i have two amd athlon 1900+ MPs... i dont know if that filter is SMP or whatnot... i'll try but i'll hope it doesnt take that long....


Thanks fred, i'm at school now, but will be home on the weekend, perhaps i'll try it out this weekend, if not, then deifinitely next, since i'll have 3 days to tinker.

are you back from europe? how was your trip?


btw: what exactly dont you like about CCE? i have noticed a lot of jagged lines on many straight edges as they move, similiar to not enabling anti-aliasing on videogames, etc. This was also present in the original DV video when i hook it up directly to the tv using just regular AV cords. Is there an encoder that will smoothen these lines? I really thought CCE was a great encoder, i'm curious to know what you dont like, or think another would do a better job at doing, especially dv?

[FredThompson]

Post a few frames of DV showing the artifact you mention. 5 frames should be enough.

CCE doesn't do that great a job at fairly low bitrates. If you are happy with 2 hours on a DVDR, fine, use it. Compression can be better. I've been using TMPGEnc lately and will test the latest HC release soon. (Wish he'd get with jdiner and make some mods so HC will play nice with TyTool...)

[ou8thisSN]

i'll upload a few frames when i get hope and bump this thread... i have no dv saved on my laptop here. I usually put about 55-64 minutes on each DVD-R, the equivalent of one DV tape, so the bitrates dont dip low. i usually encode at 9800 max 8000avg and 2000 min

[ou8thisSN]

hey fred, i'm hoping bumping this thread will get your attention here. Do I need your white balance function? i know its silly to ask, but how do i know i need it? I was a little confused by your comments about not letting Avisynth deinterlace becuase it throws away half the information. how do i stop it from doing so, or is this even a problem for me, based on the DV => DVD script posted on the main guide. I hope I didnt throw away half my resolution after converting 30 tapes already.