Help to convert deinterlace script to interlace.

[vigi_lante]

I would like to know which changes I need to do on the above script so I can process a NTSC TV capture interlaced anime, using the same filters and options. I was using this script to process the same source, but I'm don't want to deinterlace it anymore, and since this script is made for deinterlaced source, I would like to know what I need to change. Thanks.


src=AviSource("c:\capture.avi")

src=Decimate(src)

src=ConvertToYV12(src)

src=UnDot(src)

src=cnr2(src)

src=edeen(src,7,14,21,2,3,true)

src=TemporalCleaner(src,6,12)

src=aWarpSharp(src)

src=mfToonLite(src)

src=BicubicResize(src,512,384)

src=Limiter(src)

[Mug Funky]

how about:


AviSource("c:\capture.avi")
Decimate() # why is this here?
ConvertToYV12(interlaced=true)

even=last.separatefields().selecteven()
odd=last.separatefields().selectodd()

even = even.UnDot().cnr2().edeen(7,14,21,2,3,true)
\ .TemporalCleaner(6,12).aWarpSharp().mfToonLite()
\ .BicubicResize(512,384/2).Limiter()

odd = odd.UnDot().cnr2().edeen(7,14,21,2,3,true)
\ .TemporalCleaner(6,12).aWarpSharp().mfToonLite()
\ .BicubicResize(512,384/2).Limiter()

interleave(even,odd) # or odd,even if field order requires it


or better still, but maybe slower:

AviSource("c:\capture.avi")
ConvertToYV12(interlaced=true)

assumetff() #change this if field order is the other way

kernelbob(order=1) # change order to 0 for bff, and use
# the latest kerneldeint - it's hella fast

UnDot()
cnr2()
edeen(7,14,21,2,3,true)
TemporalCleaner(6,12)
aWarpSharp()
mfToonLite()
BicubicResize(512,384)
Limiter()

separatefields().selectevery(4,1,2) # 4,0,3 for bff
weave()