Also, do you want borders cropped, or not.
Bit more info required.
(eg, What is source, eg BlueRay[DGIndexNV], DVD[DGIndex], MP4 file ???, What is dest, Blueray, DVD, etc ???)
EDIT: Some funcs in RT_Stats,
*****************************************************
****** SCRIPT CONVERSION TO PLUGIN FUNCTIONS ********
*****************************************************
Below fns converted from previously existing script functions which will also be supplied so that you can see the logic,
any changes after v1.10 plugin versions may not be reflected in the later script versions.
RT_GetSAR(clip,dar float)
Gets Sample (pixel) Aspect Ratio from DAR Display Aspect Ratio.
***
***
***
RT_GetDAR(clip,sar float)
Gets DAR Display Aspect Ratio from SAR, Sample (pixel) Aspect Ratio.
***
***
***
RT_SignalDAR(float) # See Megui wiki (name change from SetDAR)
Signal DAR to MEGUI. Sets Global vars MeGUI_darX and MeGUI_darY which are read during MEGUI loading of AVS file.
***
***
***
RT_SignalDAR2(int darx,int dary)
As for RT_SignalDAR() except it allows setting of numerator and denominator individually.
Signal DAR to MEGUI. Sets Global vars MeGUI_darX and MeGUI_darY which are read during MEGUI loading of AVS file.
***
***
***
RT_GetCropDAR(clip,float DAR,float "X"=0,float "Y"=0,Float"W"=0,float "H"=0)
Call prior to Crop/Resize with (possibly fractional) cropping to calc resultant DAR, X,Y,W,H are cropping coords
DAR = FAR * SAR ::: FAR = DAR / SAR ::: SAR = DAR / FAR
Cropping affects FAR & usually DAR, resizing does not affect DAR (unless also cropped). Resizing affects FAR and maybe SAR.
We dont allow eg -ve X
Script equivlents,
Function GetCropDAR(clip c,float DAR,float "X",float "Y",float "W",float "H") {
# Call prior to Crop/Resize with (possibly fractional) cropping to calc resultant DAR, X,Y,W,H are cropping coords
# DAR = FAR * SAR ::: FAR = DAR / SAR ::: SAR = DAR / FAR
#
X=Float(Default(X,0.0)) Y=Float(Default(Y,0.0)) W=Float(Default(W,0.0)) H=Float(Default(H,0.0))
W=W<=0.0?c.width+W-X:W H=H<=0.0?c.height+H-Y:H
Assert(X>=0.0&&X < c.width, "GetCropDAR: Invalid X("+String(X)+")")
Assert(Y>=0.0&&Y < c.height,"GetCropDAR: Invalid Y("+String(Y)+")")
Assert(W> 0.0&&X+W<=c.width, "GetCropDAR: Invalid W("+String(W)+")")
Assert(H> 0.0&&Y+H<=c.height,"GetCropDAR: Invalid H("+String(H)+")")
Return c.GetSAR(DAR) * W / H
}
#--------------
# From MeGUI Wiki:
Function GetDAR(clip c, float SAR) { return Float(c.width) * SAR / Float(c.height)} # Gets the DAR from the SAR
Function GetSAR(clip c, float DAR) { return DAR * Float(c.height) / Float(c.width) } # Gets the SAR from the DAR
Function SignalDAR(float DAR){ # Signal DAR for MEGUI (Name change from SetDar)
Assert(DAR>0.0, "SignalDAR: Error, DAR must be greater than zero")
Global MeGUI_darx=Round(1000*DAR) Global MeGUI_dary=1000
}
Function SignalDAR2(int DARX,int DARY){
Assert(DARX>0 && DARY>0, "SignalDAR2: Error, DARX and DARY must be greater than zero")
Global MeGUI_darx=DARX Global MeGUI_dary=DARY
}
The SignalDAR stuff is to signal AR to MeGUI.
SAR = Sample Aspect Ration, ie per pixel.
FAR = Frame Aspect Ratio, ie size in pixels.
DAR = Required display Shape.
When you crop something SAR (Sample, ie pixel size) does not change.
So if known DAR, find the SAR with GetSAR().
Crop and find current DAR via GetDAR().
################################
EDIT:
Here a small part of massive script, it would initially call sub fuction to auto crop, then left to user to manually set crop coords
and comment out the DoSeq() call. This to avoid long timouts in MeGUI as it would call the pre-processing auto crop stuff up to about 7 times.
This script does not try to keep borders at all, meant for final viewing MPG/MP4/MKV only, not for encode to BlueRay or DVD.
SOURCE_CLIP = Last
SOURCE_DAR=16/9.0
SOURCE_SAR=SOURCE_CLIP.RT_GetSAR(SOURCE_DAR)
RT_DebugF("SOURCE_DAR=%f SOURCE_SAR=%f",SOURCE_DAR,SOURCE_SAR)
return Doseq # This is a call to script which auto crops source and shows crop coords which should be user set below.
# Then this line commented out
CROP_X=0 CROP_Y=0 CROP_W=-0 CROP_H=-0
SOURCE_CLIP.crop(CROP_X,CROP_Y,-ABS(CROP_W),-ABS(CROP_H))
Global G_QBC=FALSE # switch off future autocrop
BORDER_CROPPED_DAR=RT_GetDAR(SOURCE_SAR)
RT_DebugF("Border Cropped DAR=%f",BORDER_CROPPED_DAR)
AR_MAX = 2.21 # Maximum Aspect Ratio, Width cropped if greater.
AR_MIN = 0.0 # Minimum Aspect Ratio, Height cropped if Lesser.
############
# Required Output Dimensions control.
# dim = -1 ) As original Dimension after Border & Aspect Ratio Limiting cropping.
# dim = -ve ) Min(original Dimension after Border & Aspect Ratio Limiting cropping, Abs(dim after cropping))
# dim = +ve ) Dimension is set to the explicitly set value that is greater than 0.
# dim = 0 ) This dimension is FAR (Frame Aspect Ratio) resized using the alternate dimension and SAR 1:1 [so is same as original cropped DAR <after border and Aspect ratio Limiting>]
# OUTPUT_W and OUTPUT_H CANNOT BOTH be 0, else Error.
############
OUTPUT_W = 0
OUTPUT_H = -1
###
Assert(OUTPUT_W!=0 || OUTPUT_H!=0,"OUTPUT_W and OUTPUT_H Cannot both be zero")
BORDERCROPPED_CLIP=Last
W=Width H=Height FAR = W/Height.Float
if(FAR*SOURCE_SAR > AR_MAX) { # WIDTH CROPPED to AR_MAX # Cropping does not change SAR
RT_DebugF("WIDTH cropping to AR_MAX")
Sub_W = Round((W - (H * AR_MAX / SOURCE_SAR))/4) * 4
Sub_Lft = Sub_W / 2
Sub_Rgt = Sub_W - Sub_Lft
New_W = W - Sub_Lft - Sub_Rgt
CROP_X = CROP_X+Sub_Lft
CROP_W = -(ABS(CROP_W)+ABS(Sub_Rgt))
CROP_H = -ABS(CROP_H)
RT_DebugF("Aspect Ratio Limit crop(%d,0,%d,0)",Sub_Lft,Sub_Rgt)
Last = SOURCE_CLIP.crop(CROP_X,CROP_Y,CROP_W,CROP_H)
AR_LIMITED_DAR = Last.RT_GetDAR(SOURCE_SAR) # Cropping (usually) affects DAR
RT_DebugF("New DAR=%.3f",AR_LIMITED_DAR)
} Else if(FAR*SOURCE_SAR < AR_MIN) { # HEIGHT CROPPED to AR_MIN # Cropping does not change SAR
RT_DebugF("HEIGHT cropping to AR_MIN")
Sub_H = Round((H - (W / AR_MIN * SOURCE_SAR))/4) * 4
Sub_Top = Sub_H / 2
Sub_Bot = Sub_H - Sub_Top
New_H = H - Sub_Top - Sub_Bot
CROP_Y = CROP_Y+Sub_Top
CROP_H = -(ABS(CROP_H)+ABS(Sub_Bot))
CROP_W = -ABS(CROP_W)
RT_DebugF("Aspect Ratio Limit crop(0,%d,0,%d)",Sub_Top,Sub_Bot)
Last = SOURCE_CLIP.crop(CROP_X,CROP_Y,CROP_W,CROP_H)
AR_LIMITED_DAR = Last.RT_GetDAR(SOURCE_SAR) # Cropping (usually) affects DAR
RT_DebugF("New DAR=%.3f",AR_LIMITED_DAR)
} Else {
RT_DebugF("NO AR CROPPING")
AR_LIMITED_DAR = Last.RT_GetDAR(SOURCE_SAR) # Cropping (usually) affects DAR
}
AR_LIMTED_CLIP=Last
if(OUTPUT_W > 0 && OUTPUT_H > 0) { # Explicit dual dimension resize, DAR same as frame AR
Global G_DISPWID = ((OUTPUT_W / 4.0) * 4).Round
Global G_DISPHIT = ((OUTPUT_H / 4.0) * 4).Round
OUT_S = RT_String("Output Width based on Explicit Width[%d]",OUTPUT_W)
OUT_S = RT_String("%s\nOutput Height based on Explicit Height[%d]",OUT_S,OUTPUT_H)
FAR = G_DISPWID.Float / G_DISPHIT
OUT_SAR = 1.0
}Else {
If(OUTPUT_W == 0) { # 1:1 Resizing Width
Global G_DISPHIT = (OUTPUT_H > 0) ? OUTPUT_H : (OUTPUT_H == -1 ) ? Last.Height : Min(Last.Height,Abs(OUTPUT_H))
Global G_DISPHIT = Round(G_DISPHIT / 4.0) * 4
Global G_DISPWID = Round(G_DISPHIT.Float * AR_LIMITED_DAR / 4.0) * 4
OUT_S = RT_String("Output 1:1 Resizing Width based on %s Height[%d]",(OUTPUT_H > 0)?"Explicit":"AR_MAX",G_DISPHIT)
}Else if(OUTPUT_H==0) { # 1:1 Resizing Height
Global G_DISPWID = (OUTPUT_W > 0) ? OUTPUT_W : (OUTPUT_W == -1) ? Last.Width : Min(Last.Width,Abs(OUTPUT_W))
Global G_DISPWID = Round(G_DISPWID / 4.0) * 4
Global G_DISPHIT = Round(G_DISPWID.Float / AR_LIMITED_DAR / 4.0) * 4
OUT_S = RT_String("Output 1:1 Resizing Height based on %s Width[%d]",(OUTPUT_W > 0)?"Explicit":"AR_MAX",G_DISPWID)
} Else { # Not 1:1 Resize : Both W and H dims set via pre-cropped size or explicit size.
Global G_DISPWID = (OUTPUT_W > 0) ? OUTPUT_W : (OUTPUT_W == -1) ? Last.Width : Min(Last.Width,Abs(OUTPUT_W))
Global G_DISPWID = Round(G_DISPWID / 4.0) * 4
Global G_DISPHIT = (OUTPUT_H > 0) ? OUTPUT_H : (OUTPUT_H == -1 ) ? Last.Height : Min(Last.Height,Abs(OUTPUT_H))
Global G_DISPHIT = Round(G_DISPHIT / 4.0) * 4
OUT_S = RT_String("Output Width based on %s Width[%d]",(OUTPUT_W > 0)?"Explicit":"AR_MAX",G_DISPWID)
OUT_S = RT_String("%s\nOutput Height based on %s Height[%d]",OUT_S,(OUTPUT_H > 0)?"Explicit":"AR_MAX",G_DISPHIT)
}
FAR = G_DISPWID.Float / G_DISPHIT
OUT_SAR = AR_LIMITED_DAR / FAR
}
Global G_ASPECT_DARX=Round(G_DISPWID * OUT_SAR * 1000) Global G_ASPECT_DARY=Round(G_DISPHIT * 1000)
ORG=Last
Doseq
RT_DebugF("Source: Width=%d Height=%d : SAR=%.3f DAR=%.3f",Source_Clip.Width,Source_Clip.Height,SOURCE_SAR,SOURCE_DAR)
RT_DebugF("Border Cropped: Width=%d Height=%d : SAR=%.3f DAR=%.3f",BORDERCROPPED_CLIP.Width,BORDERCROPPED_CLIP.Height,SOURCE_SAR,BORDER_CROPPED_DAR)
RT_DebugF("AR_LIMITED Cropped: Width=%d Height=%d : SAR=%.3f DAR=%.3f",AR_LIMTED_CLIP.Width,AR_LIMTED_CLIP.Height,SOURCE_SAR,AR_LIMITED_DAR)
RT_DebugF("%s",OUT_S)
RT_DebugF("Output: Width=%d Height=%d : SAR=%.3f DAR=%.3f",Width,Height,OUT_SAR,Last.RT_GetDAR(OUT_SAR))
Above for hint only, not a solution for you.
NOTE, I dont like DAR that is really wide, eg 2.5,nasty skinny strip in screen center.
So, I limit(ie crop) my clips to a max DAR of 2.21 (which is enough for nearly all movies without cropping important text).
2.21 Is also DAR of my Samsung phone.
EDIT: Above script uses "SOURCE_DAR=16/9.0", this script is used for Blueray decode, if was 4.0/3.0 AR then I would manually change it to such. (Or use a different DGIndexNV template, which above script is part of).
EDIT: Oh, G_DISPWID, G_DISPHIT, are output resize dimensions.
EDIT: Looks like HelloHello has got you sorted out good. :)