Gee TC (is that 'Top Cat' ?)
Can you try this out, no idea if it does as it is supposed to, dont do anything on the two clips (1 anime) that I tried it on, (but then the original
script did not seem to do anything either).
Function GameDropFixV4_MI(clip c, bool "myGPU", bool "myDebug", int "myErrSize",int "threads",int "MtMode") {
c
myGPU = default( myGPU, true )
myDebug = default( myDebug, false )
myErrSize = default( myErrSize, 12 )
threads = default( threads, 1 )
MtMode = default(MtMode,0) # default 0, dont call SetMtMode
###
Func_S=("""
super_params_mini = (myGPU==true) ? "{gpu:1}" : "{gpu:0}"
analyse_params_mini="{block:{w:8,h:8}}"
miniW = max(int(width/64)*32,320)
miniH = max(int(height/64)*32,160)
mini = BicubicResize(miniW,miniH).TemporalSoften(1, 1, 0, scenechange=1, mode=2)
super_mini=mini.SVSuper(super_params_mini)
vectors_mini=SVAnalyse(super_mini, analyse_params_mini)
vectors_Forward=SVConvert(vectors_mini, false)
HorizontalSpeed_luma=mini.MMask(vectors_Forward, kind=3).convertToRGB32().PointResize(miniW/8, miniH/8)
\ .PointResize(miniW/4, miniH/4).ConvertToYV12().mt_lut(y=2, u=128, v=128)
VerticalSpeed_luma=mini.MMask(vectors_Forward, kind=4).convertToRGB32().PointResize(miniW/8, miniH/8)
\ .PointResize(miniW/4, miniH/4).ConvertToYV12().mt_lut(y=2, u=128, v=128)
###
size=16
luma_lft = HorizontalSpeed_luma.crop(0,0,miniW/16,0).BicubicResize(size,size)
luma_rgh = HorizontalSpeed_luma.crop(miniW/16+miniW/8,0,0,0).BicubicResize(size,size)
luma_top = VerticalSpeed_luma.crop(0,0,0,miniH/16).BicubicResize(size,size)
luma_btm = VerticalSpeed_luma.crop(0,miniH/16+miniH/8,0,0).BicubicResize(size,size)
luma_drop = luma_lft.mt_lut(y=-1, u=128, v=128)
###
super_params = (myGPU==true) ? "{gpu:1}" : "{gpu:0}"
analyse_params="{main:{search:{coarse:{distance:4,bad:{sad:2000}},type:2,distance:4},penalty:{lambda:1,pglobal:10000}},refine:[{thsad:65000}]}"
smoothfps_params="{rate:{num:12,den:1},algo:13,scene:{blend:true}}"
super = SVSuper(super_params)
vectors = SVAnalyse(super, analyse_params)
fix_all = SVSmoothFps(super, vectors, smoothfps_params, mt=threads, url="www.svp-team.com")
###
Function FnA@@@(clip luma_drop,clip mini,clip luma_lft,clip luma_rgh,clip luma_top,clip luma_btm,Int move_idx,Int y_idx,
\ Float min_move,Float max_stop) {
luma_drop n = current_frame
AvgLuma_lft = 128.0-luma_lft.RT_AverageLuma(n=n)
AvgLuma_rgh = 128.0-luma_rgh.RT_AverageLuma(n=n)
AvgLuma_lft_prev = 128.0-luma_lft.RT_AverageLuma(n=n,delta=-1)
AvgLuma_rgh_prev = 128.0-luma_rgh.RT_AverageLuma(n=n,delta=-1)
AvgLuma_lft_next = 128.0-luma_lft.RT_AverageLuma(n=n,delta= 1)
AvgLuma_rgh_next = 128.0-luma_rgh.RT_AverageLuma(n=n,delta= 1)
AvgLuma_top = 128.0-luma_top.RT_AverageLuma(n=n)
AvgLuma_btm = 128.0-luma_btm.RT_AverageLuma(n=n)
AvgLuma_top_prev = 128.0-luma_top.RT_AverageLuma(n=n,delta=-1)
AvgLuma_btm_prev = 128.0-luma_btm.RT_AverageLuma(n=n,delta=-1)
AvgLuma_top_next = 128.0-luma_top.RT_AverageLuma(n=n,delta= 1)
AvgLuma_btm_next = 128.0-luma_btm.RT_AverageLuma(n=n,delta= 1)
Max_lft = max(abs(AvgLuma_lft_prev),abs(AvgLuma_lft),abs(AvgLuma_lft_next))
Max_rgh = max(abs(AvgLuma_rgh_prev),abs(AvgLuma_rgh),abs(AvgLuma_rgh_next))
Max_top = max(abs(AvgLuma_top_prev),abs(AvgLuma_top),abs(AvgLuma_top_next))
Max_btm = max(abs(AvgLuma_btm_prev),abs(AvgLuma_btm),abs(AvgLuma_btm_next))
Max_all = max(Max_lft,Max_rgh,Max_top,Max_btm)
MaxLuma=max(abs(AvgLuma_lft),abs(AvgLuma_rgh),abs(AvgLuma_top),abs(AvgLuma_btm))
MaxLuma_prev=max(abs(AvgLuma_lft_prev),abs(AvgLuma_rgh_prev),abs(AvgLuma_top_prev),abs(AvgLuma_btm_prev))
MaxLuma_next=max(abs(AvgLuma_lft_next),abs(AvgLuma_rgh_next),abs(AvgLuma_top_next),abs(AvgLuma_btm_next))
dif = mini.RT_YDifference(n=n,delta=-1) # from previous
dif_next = mini.RT_YDifference(n=n,delta= 1) # to next
dif_prev = mini.RT_YDifference(n=n-1,delta=-1) # n-1 -> n-2
GoodContrast = (max(mini.RT_YPlaneMinMaxDifference(n=n),mini.RT_YPlaneMinMaxDifference(n=n+1))>20)
drop = (MaxLuma<0.1 && MaxLuma*2<max(MaxLuma_prev,MaxLuma_next) && dif*y_idx<max(dif_prev,dif_next)) ? 1 : 0
if(dif*y_idx<max(dif_prev,dif_next)) {
drop_lft = (AvgLuma_lft_prev*AvgLuma_lft_next>0 && abs(AvgLuma_lft*move_idx)<Max_lft && abs(AvgLuma_lft)<=min_move) ? 2 : 0
drop_rgh = (AvgLuma_rgh_prev*AvgLuma_rgh_next>0 && abs(AvgLuma_rgh*move_idx)<Max_rgh && abs(AvgLuma_rgh)<=min_move) ? 3 : 0
drop_top = (AvgLuma_top_prev*AvgLuma_top_next>0 && abs(AvgLuma_top*move_idx)<Max_top && abs(AvgLuma_top)<=min_move) ? 4 : 0
drop_btm = (AvgLuma_btm_prev*AvgLuma_btm_next>0 && abs(AvgLuma_btm*move_idx)<Max_btm && abs(AvgLuma_btm)<=min_move) ? 5 : 0
if(drop == 0 && MaxLuma<Max_stop) {
drop = ( Max_lft==Max_all) ? drop_lft : drop
drop = (drop==0 && Max_rgh==Max_all) ? drop_rgh : drop
drop = (drop==0 && Max_top==Max_all) ? drop_top : drop
drop = (drop==0 && Max_btm==Max_all) ? drop_btm : drop
}
} else {drop_lft=0 drop_rgh=0 drop_top=0 drop_bot=0}
drop_dif = (dif<0.4 && MaxLuma<min_move) ? 6 : 0
drop = (drop==0 && drop_dif>0) ? drop_dif : drop
drop = (drop>0 && Max_all<0.1) ? 0 : drop
drop = (drop>0 && !GoodContrast) ? 0 : drop
luma = mini.RT_AverageLuma(n=n)
luma_next = mini.RT_AverageLuma(n=n,delta= 1)
max_luma = max(luma,luma_next)
drop = (drop>0 && max_luma<16.5) ? 0 : drop
(drop>0) ? last : \
(Max_lft==Max_all) ? luma_lft : \
(Max_rgh==Max_all) ? luma_rgh : \
(Max_top==Max_all) ? luma_top : luma_btm
Return Last
}
# Local arg names for constants import
move_idx = 5
y_idx = 3
min_move = 0.1
max_stop = 0.5
ARGS1 = "mini,luma_lft,luma_rgh,luma_top,luma_btm,move_idx,y_idx,min_move,max_stop"
drop_clip = luma_drop.GScriptClip("FnA@@@(last, "+ARGS1+")", local=true, args=ARGS1,after_frame=true)
################
Function FnB@@@(clip drop_clip,clip fix_r50,clip fix_lr33,clip fix_l50,clip fix_r133,clip fix_r66,
\ Float AvgDrop,Float MaxMulty,float dblMulti,Float max_stop) {
drop_clip n = current_frame
AvgLuma_prev2 = abs(128.0-Last.RT_averageLuma(n=n,delta=-2))
AvgLuma_prev = abs(128.0-Last.RT_averageLuma(n=n,delta=-1))
AvgLuma = abs(128.0-Last.RT_AverageLuma(n=n))
AvgLuma_next = abs(128.0-Last.RT_averageLuma(n=n,delta= 1))
AvgLuma_next2 = abs(128.0-Last.RT_averageLuma(n=n,delta= 2))
AvgLuma_prev_ = (AvgLuma_prev==AvgDrop) ? 0 : AvgLuma_prev
AvgLuma_next_ = (AvgLuma_next==AvgDrop) ? 0 : AvgLuma_next
RightZero = (AvgLuma_prev_*MaxMulty<AvgLuma_next_ && (AvgLuma_prev_>max_stop || AvgLuma_next_>max_stop)) ? 1 : 0
LeftZero = (AvgLuma_next_*MaxMulty<AvgLuma_prev_ && (AvgLuma_prev_>max_stop || AvgLuma_next_>max_stop)) ? 1 : 0
drop = (AvgLuma==AvgDrop && AvgLuma_next==AvgDrop) ? -50 : 0
drop = (AvgLuma==AvgDrop && AvgLuma_prev==AvgDrop) ? 50 : drop
drop = (drop==0 && AvgLuma==AvgDrop && LeftZero==0 && RightZero==0) ? \
AvgLuma_prev_>AvgLuma_next_*dblMulti ? -50 : \
AvgLuma_prev_*dblMulti>=AvgLuma_next_ ? AvgLuma_next2==AvgDrop ? 50 : 33 : 50 : drop
drop = (drop==0 && AvgLuma==AvgDrop && RightZero==0 && AvgLuma_next2==AvgDrop) ? -50 : drop
drop = (drop==0 && AvgLuma==AvgDrop && LeftZero==0 && AvgLuma_prev2==AvgDrop) ? 66 : drop
(drop==50) ? fix_r50 : \
(drop==33) ? fix_lr33 : \
(drop==-50) ? fix_l50 : \
(drop==133) ? fix_r133 : \
(drop==66) ? fix_r66 : drop_clip
Return Last
}
# Local arg names for constants import
fix_r50 = luma_lft.mt_lut(y=-1, u=128, v=128)
fix_lr33 = luma_lft.mt_lut(y=-2, u=128, v=128)
fix_l50 = luma_lft.mt_lut(y=-3, u=128, v=128)
fix_r133 = luma_lft.mt_lut(y=-4, u=128, v=128)
fix_r66 = luma_lft.mt_lut(y=-5, u=128, v=128)
AvgDrop = 127.0
MaxMulty = 10.0
dblMulti = 1.3
max_stop = 0.5
ARGS2 = "fix_r50,fix_lr33,fix_l50,fix_r133,fix_r66,AvgDrop,MaxMulty,dblMulti,max_stop"
fix_clip = drop_clip.GScriptClip("FnB@@@(last, "+ARGS2+")", local=true, args=ARGS2,after_frame=true)
################
Function FnC@@@(clip clp,clip fix_clip,clip fix50,clip fix33,clip fix66,clip fix66p,clip fix75,clip fix50n,clip fix133,clip fix125,
\ Int r50,Int lr33,Int l50,Int r133,Int r66, fix75_prv,fix66_prv,fix50n_prv,fix125_nxt,fix133_nxt) {
clp n = current_frame
AvgFix_prev = fix_clip.RT_AverageLuma(n=n,delta = -1)
AvgFix = fix_clip.RT_AverageLuma(n=n,delta = 0)
AvgFix_next = fix_clip.RT_AverageLuma(n=n,delta = 1)
AvgFix_next2 = fix_clip.RT_AverageLuma(n=n,delta = 2)
AvgFix_next3 = fix_clip.RT_AverageLuma(n=n,delta = 3)
/*
(AvgFix==r50) \
? (AvgFix_next2==lr33 || AvgFix_next2==l50) ? fix33 : fix50 : \
(AvgFix==lr33) ? fix33 : \
(AvgFix_next==lr33) \
? (AvgFix_prev==r66) ? fix75.trim(1,1)+fix75 : fix66.trim(1,1)+fix66 : \
(AvgFix_next==l50) \
? (AvgFix_prev==lr33 || AvgFix_prev==r50) ? fix66.trim(1,1)+fix66 : \
(AvgFix_prev==r66) ? fix75.trim(1,1)+fix75 : fix50n.trim(1,1)+fix50n : \
(AvgFix==r66) \
? (AvgFix_next2==lr33 || AvgFix_next2==l50) ? fix50 : fix66p : \
(AvgFix_next==r66) \
? (AvgFix_next3==lr33 || AvgFix_next3==l50) ? fix125.trim(1,0) : fix133.trim(1,0) : \
last
*/
if(AvgFix==r50) {
(AvgFix_next2==lr33 || AvgFix_next2==l50) ? fix33 : fix50
} else if(AvgFix==lr33) {
fix33
} else if(AvgFix_next==lr33) {
(AvgFix_prev==r66) ? fix75_prv : fix66_prv
} else if(AvgFix_next==l50) {
if(AvgFix_prev==lr33 || AvgFix_prev==r50) {
fix66_prv
} else if(AvgFix_prev==r66) {
fix75_prv
} else {
fix50n_prv
}
}else if(AvgFix==r66) {
(AvgFix_next2==lr33 || AvgFix_next2==l50) ? fix50 : fix66p
} else if(AvgFix_next==r66) {
(AvgFix_next3==lr33 || AvgFix_next3==l50) ? fix125_nxt : fix133_nxt
} else {
Last
}
}
# Local arg names for constants import
fix50 = fix_all.SelectEvery(12,6)
fix33 = fix_all.SelectEvery(12,4)
fix66 = fix_all.SelectEvery(12,8)
fix66p = fix_all.SelectEvery(12,8)
fix75 = fix_all.SelectEvery(12,9)
fix50n = fix_all.SelectEvery(12,6)
fix133 = fix_all.SelectEvery(12,4)
fix125 = fix_all.SelectEvery(12,3)
if(myDebug) { # These are for visual debugging (the "Subtitle" clauses)
fix50 = fix50.Subtitle("fix50", align=3, size=myErrSize)
fix33 = fix33.Subtitle("fix33", align=3, size=myErrSize)
fix66 = fix66.Subtitle("-fix33", align=3, size=myErrSize)
fix66p = fix66p.Subtitle("fix66", align=3, size=myErrSize)
fix75 = fix75.Subtitle("-fix25", align=3, size=myErrSize)
fix50n = fix50n.Subtitle("-fix50", align=3, size=myErrSize)
fix133 = fix133.Subtitle("fix133", align=3, size=myErrSize)
fix125 = fix125.Subtitle("fix125", align=3, size=myErrSize)
}
fix75_prv = fix75.Trim(0,-1)++fix75
fix66_prv = fix66.Trim(0,-1)++fix66
fix50n_prv = fix50n.Trim(0,-1)++fix50n
fix125_nxt = fix125.Trim(1,0)
fix133_nxt = fix133.Trim(1,0)
r50 = 1
lr33 = 2
l50 = 3
r133 = 4
r66 = 5
ARGS3 = "fix_clip,fix50,fix33,fix66,fix66p,fix75,fix50n,fix133,fix125,r50,lr33,l50,r133,r66, fix75_prv,fix66_prv,fix50n_prv,fix125_nxt,fix133_nxt"
Last.GScriptClip("FnC@@@(last, "+ARGS3+")", local=false, args=ARGS3,after_frame=true)
""") ### End of Func_S
#######################################
# Unique Identifier Definition
#######################################
GIFunc ="GDF" # Function Name, Supply unique name for your multi-instance function.
GIName =GIFunc+"_InstanceNumber" # Name of the Instance number Global
RT_IncrGlobal(GIName) # Increment Instance Global (init to 1 if not already exists)
GID = GIFunc + "_" + String(Eval(GIName))
Func_S = RT_StrReplace(Func_S,"@@@","_"+GID)
# RT_WriteFile("DEBUG"+GID+".TXT","%s",Func_S) # Uncomment to output DEBUG text to file (with same line numbers as GSCript errors)
Last = GScript(Func_S)
(MtMode>0) ? SetMTMode(MtMode) : NOP
trim(0,framecount-threads)
}
The stuff in BLUE is original code, not sure if I did conversion to GScript correctly (I have my own way of using ternary conditional [(condition)?:], and
the way it was coded was back-to-front to how I would have done it)
Ive done as Multi-Instance script, real pig to debug the 1st 2 scriptclips as results are so tiny (and cannot read error message).
Anyway, now that its GSCript capable, author can possibly improve logic, I did not want to change too much as I had no idea
what the intent was, (not even sure what its supposed to do).
Anyways, needs GScript, Grunt and RT_Stats.
Let us know how it goes, if it works OK.