Jmac, see below PlanetCrop() works great, even with your 2nd moon image set.
#import("D:\AVS\BANK\QueryLumaMinMax.avsi")
Fn="D:\MOON\*.JPG|BMP"
BAFFLE = 12 # Number of consecutive scanlines that need to pass, below considered noise.
BLK = 32 # Where black sky can vary in brightness
GROW_W = 256 # Enlarge canvas width by GROW_W pixels (keep surround area, Use with KEEP_MARGIN)
GROW_H = 256 # Enlarge canvas height by GROW_H pixels
FAR = 1.0 # Frame Aspect Ratio
STRENGTH = 1.0 # AutoLevel Strength 0.0 -> 1.0
SHOWAL = True # Right Hand Side Only AutoLeveled
KEEP = true # True tries to keep some of the cropped area instead of AddBorders
SHOWKEEP = true # Show Kept margin
SHOWBORDER = true # True Show replaced border in Red, else Black. (FAR affects) (Test CROP)
DEBUG = True
Return PlanetCrop(Fn,BAFFLE,BLK,GROW_W,GROW_H,FAR,STRENGTH,SHOWAL,KEEP,SHOWKEEP,SHOWBORDER,DEBUG)
#--------------------------------------------------------------------------------
Function PlanetCrop(String "FileName",int "Baffle",Int "BlackRange",int "Grow_W",int "Grow_H",Float "FAR", \
Float "AutoLevelStrength",bool "ShowAutoLevel",bool "KeepMargin",bool "ShowMargin",bool "ShowBorder",bool "Debug") {
# PlanetCrop v1.0 - 16 Dec 2012
#
# Requires GScript, RT_Stats and QueryLumaMinMax.avs
#
# Given a series of time lapse planetoid images, locates those images in frame, crops out and joins them all together into
# a video clip of required Frame Aspect Ratio, 1 FPS, with optional Auto Luma Levelling.
# First scans each image establishing maximum dimensions for whole sequence (after cropping out the planets). Optionally 'grows' those
# dimensions to maintain some of the area around the cropped planets. A 'canvas' size is then established to contain the now maximum
# dimensions and respecting the desired Frame Aspect Ratio, synthetic black borders are added where necessary.
# Borders are the areas added to maintain aspect ratio and can be hi-lited in red. Margins are areas that use the
# original image content instead of synthetic black borders (where possible), they replace synthetic borders, and can be hi-lited
# in green. Margins are the areas between the established crop coords and synthetic borders.
# --------------------------------------
# Args:-
# Filename: Default "*.BMP|JPG|JPE|JPEG|PNG|TGA|TIF|GIF|TIFF". Image Path and wildcard with mulitple pipe separated extensions.
# Baffle: Default 12. Number of scanlines that must break a threshold to be accepted as 'planet'. Avoids noise.
# BlackRange: Default 32. Where background (sky) can vary in luminance by a significant amount.
# Grow_W,Grow_H: Default 128. Size in pixels by which to 'grow' the accumulated maximum dimensions once all planets have been identified.
# FAR: Default 4.0/3.0. Frame Aspect Ratio.
# AutoLevelStrength: Default 0.0. Auto luma leveling, range 0.0 -> 1.0. 0.0 is OFF.
# ShowAutoLevel: Default False. If true then shows Auto leveling on right hande side of image ONLY.
# KeepMargin: Default True. When padding to maintain Frame Aspect Ratio, tries to keep image instead of adding borders.
# ShowMargin: Default False. If True, shows kept margins in Green.
# ShowBorder: Default False. When padding to maintain Frame Aspect Ratio, borders are shown in red.
# Debug: Default False. Show debug info via DebugView. Need DebugView: http://technet.microsoft.com/en-gb/sysinternals/bb545027
#
VERS="PlanetCrop v1.0 - 16 Dec 2012"
FileName= Default(FileName,"*.BMP|JPG|JPE|JPEG|PNG|TGA|TIF|GIF|TIFF")
Baffle=Default(Baffle,12)
BlackRange=Default(BlackRange,32)
Grow_W=Default(Grow_W,128)
Grow_H=Default(Grow_H,128)
FAR=Float(Default(FAR,4.0/3.0))
AutoLevelStrength=Float(Default(AutoLevelStrength,0.0))
ShowAutoLevel=Default(ShowAutoLevel,false)
KeepMargin=Default(KeepMargin,True)
ShowMargin=Default(ShowMargin,False)
ShowBorder=Default(ShowBorder,False)
DEBUG=Default(DEBUG,False)
# Lesser changed stuff Hardcoded
BORDER = (ShowBorder) ? $FF0000 : $000000 # Color for replaced borders.
MARGINBORDER= $00FF00 # Color for KEEP_MARGIN borders.
DEBUG_QLMM = False # Debug QueryLumaMinMax
FPS = 1.0 # Whatever.
WMOD = 1
HMOD = 1
OUT_FILE = "PLANET.List"
Assert(Baffle>0,"Baffle must be 1 or more")
Assert(BlackRange>=0,"BlackRange must be 1 or more")
Assert(Grow_W>=0,"Grow_W Cannot be -ve")
Assert(Grow_H>=0,"Grow_H Cannot be -ve")
Assert(FAR>0.0,"FAR must be greater than 0.0")
Assert(AutoLevelStrength>=0.0 && AutoLevelStrength <= 1.0,"AutoLevelStrength must be 0.0 -> 1.0")
#
GScript("""
Function QPC(clip c,int Baffle) {
c
Thresh=0.04 # 4%, Baffle should remove need to change
w=Width h=height
got = 0 x1 = 0 x2 = w-1 Cnt=0
For(x=0,w-1) {
th=RT_YInRange(0,x=x,y=4,w=1,h=-4,lo=2,hi=255,Matrix=2) # PC levels and skip end 4 pixels (crud around frame edge)
if(got==0) {
if(th > Thresh) {
Cnt=Cnt+1
if(Cnt >= Baffle) {
x1=x-Baffle+1
Cnt=0
got=1
}
} else {
Cnt = 0
}
} else {
if(x2 == w-1 && th <= Thresh) {
Cnt=Cnt+1
if(Cnt >= 2) { # Weak BAFFLE on transition to black
x2=x-2
x=w
}
}
}
}
got=0 y1 = 0 y2 = h-1 Cnt=0
For(y=0,h-1) {
th=RT_YInRange(0,x=4,y=y,w=-4,h=1,lo=2,hi=255,Matrix=2)
if(got==0) {
if(th > Thresh) {
Cnt=Cnt+1
if(Cnt >= Baffle) {
y1=y-Baffle+1
Cnt=0
got=1
}
} else {
Cnt = 0
}
} else {
if(y2 == h-1 && th <= Thresh) {
Cnt=Cnt+1
if(Cnt >= 2) { # Weak BAFFLE on transition to black
y2=y-2
y=h
}
}
}
}
Return "PC_X="+String(x1)+" PC_Y="+String(y1)+" PC_W="+String(x2-x1+1)+" PC_H="+String(y2-y1+1)
}
#
if(DEBUG){ RT_Debug(" ") RT_Debug(VERS,"- By StainlessS") RT_Debug(" ") }
picclip = 0 # Dummy for now
result=RT_WriteFileList(FileName,OUT_FILE) # Create a listing file of Pic files
Assert((result!=0), "No files found")
FILELIST=RT_ReadTxtFromFile(OUT_FILE) # Get list of files
NFILES=RT_TxtQueryLines(FILELIST) # Query Number of lines in String ie number of files.
(DEBUG) ? RT_Debug("Found files = " + String(NFILES)) :NOP
# Prescan to ascertain max wid/hit of all files, also Autocrop & Auto Levels
MAXH=0 MAXW=0 # init max wid and hit
CROPCOORDS="" # Clear results array (string)
AUTOLEVELS="" # Clear AutoLevels array (string)
AUTOLEVEL=(AutoLevelStrength>0.0) # Adjust using Levels.
For(i=0,NFILES-1) {
FN=RT_TxtGetLine(FILELIST,i) # Filename of pic/vid file i
(DEBUG)?RT_Debug(String(i+1)+"/"+String(NFILES)+") Getting File dimensions",FN):NOP
k=ImageReader(FN,end=0).ConvertToRGB32()
OrgW=k.width OrgH=k.height
# For QPC
Grey=k.GreyScale()
MinLum=Grey.RT_YPlaneMin(0,threshold=0.2,Matrix=2)
Grey=Grey.Levels(MinLum+BlackRange,1.0,MinLum+BlackRange+1,0,255,Coring=false)
#
PCS=Grey.QPC(Baffle)
Eval(PCS)
k=k.Crop(PC_X,PC_Y,PC_W,PC_H)
CROPCOORDS=RT_TxtAddStr(CROPCOORDS,PCS)
if (AUTOLEVEL) {
QLMM = k.QueryLumaMinMax(debug=(DEBUG&&DEBUG_QLMM)) # Query luma levels (on cropped clip)
Eval(QLMM) # Set Avisynth vars
AUTOLEVELS=RT_TxtAddStr(AUTOLEVELS,QLMM) # Avisynth Bugfix, same as AUTOLEVELS = AUTOLEVELS + QLMM + Chr(10)
}
If(MAXW<PC_W) {MAXW=PC_W}
If(MAXH<PC_H) {MAXH=PC_H}
if (DEBUG) { # KEEP main debug messages together
RT_Debug ("Orig Width =",String(orgW),"Orig Height =",String(OrgH))
if((PC_W != OrgW) || (PC_H != OrgH)) { # Was Caused by AUTOCROP
RT_Debug("Crop Width =",String(PC_W),"Crop Height =",String(PC_H))
}
RT_Debug("MAX Width So Far =",String(MAXW),"MAX Height So Far =",String(MAXH))
(AUTOLEVEL)? RT_Debug("AutoLevel MinLuma=",String(QLMMMin)," MaxLuma =",String(QLMMMax)) : NOP
RT_Debug(" ----------------------------- ") # line separator
}
}
if(Grow_W>0 || Grow_H > 0) {
(DEBUG)?RT_Debug("Enlarging Max Width,Height to enlarge canvas"):NOP
MAXW=MAXW+Grow_W
MAXH=MAXH+Grow_H
}
maxFAR = Float(MAXW) / MAXH
if(FAR >= maxFAR) {
# Required Frame Aspect Ratio greater or same as maximum accumulated dimensions. Need to pad horizontal
canvasheight = Int((MAXH + (HMOD/2)) / HMOD) * HMOD
canvaswidth = Int((canvasheight * FAR + (WMOD/2)) / WMOD) * WMOD
} else { # Need to pad vertical
canvaswidth = Int((MAXW + (WMOD/2)) / WMOD) * WMOD
canvasheight = Int((canvaswidth / FAR + (HMOD/2)) / HMOD) * HMOD
}
if(DEBUG){
RT_Debug("SETTING CanvasWidth =",String(canvaswidth)," CanvasHeight =",String(canvasheight))
RT_Debug(" ----------------------------- ") # line separator
}
For(i=0,NFILES-1) {
FN=RT_TxtGetLine(FILELIST,i) # Filename of pic/vid file i
if(DEBUG){RT_Debug(string(i+1)+"/"+String(NFILES)+")","Processing File",FN)}
k=ImageReader(FN,end=0).ConvertToRGB32()
OrgW=k.width OrgH=k.height
Eval(RT_TxtGetLine(CROPCOORDS,i))
Left = (canvaswidth-PC_W) / 2 # Borders
Right = canvaswidth-PC_W - Left
Top = (canvasheight-PC_H) / 2
Bot = canvasheight-PC_H-Top
Left2=0 Right2=0 Top2=0 Bot2=0 # Init keep margin borders
if(KeepMargin) {
Left2 = ((PC_X<Left) ? PC_X : Left) / WMOD *WMOD
if(Left2>0) {
Left=Left-Left2
}
Right2 = (((OrgW-PC_X-PC_W)<Right) ? (OrgW-PC_X-PC_W) : Right) / WMOD * WMOD
if(Right2>0) {
Right=Right-Right2
}
Top2 = ((PC_Y<Top) ? PC_Y : Top) / HMOD *HMOD
if(Top2>0) {
Top=Top-Top2
}
Bot2 = (((OrgH-PC_Y-PC_H)<Bot) ? (OrgH-PC_Y-PC_H) : Bot) / HMOD * HMOD
if(Bot2>0) {
Bot=Bot-Bot2
}
if(!ShowMargin) {
PC_X=PC_X-Left2
PC_W=PC_W+Left2+Right2
PC_Y=PC_Y-Top2
PC_H=PC_H+Top2+Bot2
}
}
(DEBUG)? RT_Debug("Crop("+String(PC_X)+","+String(PC_Y)+","+String(PC_W)+","+String(PC_H)+")") : NOP
k=k.Crop(PC_X,PC_Y,PC_W,PC_H)
if (AUTOLEVEL) {
QAT = RT_TxtGetLine(AUTOLEVELS,i)
Eval(QAT)
if(k.IsYUV()) {
CSMin = 16
CSMax = 235
} else {
CSMin = 0
CSMax = 255
}
TMP_K=k
ALMin = Int(CSMin - ((CSMin - QLMMMin) * AutoLevelStrength) + 0.5) # Round Up
ALMax = Int(CSMax - ((CSMax - QLMMMax) * AutoLevelStrength)) # Round down
(DEBUG) ? RT_Debug("Levels("+String(ALMin)+",1.0,"+String(AlMax)+","+String(CSMin)+","+String(CSMax)+",Coring=False)") : NOP
k = k.Levels(ALMin,1.0,ALMax,CSMin,CSMax,Coring=False) # DONT EVER USE Coring
if(ShowAutoLevel) {
tmpw=k.width/4*2
LeftClip = TMP_K.Crop(0,0,tmpw,-0)
RightClip= k.Crop(tmpw,0,-0,-0)
k=StackHorizontal(LeftClip,RightClip)
}
}
if(KeepMargin && ShowMargin) {
(DEBUG) ? RT_Debug("KeepMargin AddBorders("+String(Left2)+","+String(Top2)+","+String(Right2)+","+String(Bot2)+")") : NOP
k = k.Addborders(Left2,Top2,Right2,Bot2,MARGINBORDER)
}
(DEBUG) ? RT_Debug("AddBorders("+String(Left)+","+String(Top)+","+String(Right)+","+String(Bot)+")") : NOP
k = k.Addborders(Left,Top,Right,Bot,BORDER).assumefps(fps)
picclip = (IsClip(picclip)) ? picclip ++ k : k # Append to clip so far
k=k.ConvertToRGB24() # Addborders done (bug in AddBorders rgb24)
if(DEBUG){RT_Debug(" ") RT_Debug(" ----------------------------- ")} # line separator
}
""")
return PicClip
}
Given args are just to demo the border/margin stuff.
Updated PlanetCrop() in RT_Stats zip.