Welcome to Doom9's Forum, THE in-place to be for everyone interested in DVD conversion.

Before you start posting please read the forum rules. By posting to this forum you agree to abide by the rules.

 

Go Back   Doom9's Forum > Capturing and Editing Video > Avisynth Usage

Reply
 
Thread Tools Search this Thread Display Modes
Old 7th August 2015, 18:05   #1  |  Link
SilSic
Registered User
 
Join Date: Aug 2012
Posts: 29
PIP Script doesn't work, need help please!

Hi,

the script below doesn't work. It only shows video2, and video1 isn't to see at all. Figure out main and pip are both clip2, but how come?
Tried a lot spending 5 days in a row for this whole script but I don't get it working. Google is no help or I'm just to blind. SetMTMode is also very disappointing only 6,3 works without flaw.
Can anyone fix that?
Thanks in advance

Code:
SetMTMode(6,3)
LoadPlugin("C:\Program Files (x86)\AviSynth 2.5\plugins\TUnsharp.dll")
LoadPlugin("D:\plugins\masktools2.dll")
LoadPlugin("D:\plugins\UnFilter.dll")
Import("D:\plugins\FastLineDarken 1.4x MT MOD.avsi")
LoadPlugin("D:\plugins\MSharpen.dll")
Import("D:\plugins\PanoramaWR2.avs")

clip1=DirectShowSource("Video1.mkv")
clip2=DirectShowSource("Video2.avi",audio=false).convertfps(29.976)

SetMTMode(6,3)

FastLineDarkenmod(clip1, strength=70,thinning=75)

SetMTMode(3,3)
MSharpen(clip1,threshold=39, strength=40,mask=false, highq=true)
PanoramaWR2(clip1,1024,480, Strength=0.900, AxisShare=0.667) 

SetMTMode(6,3)
aWarp4(Spline36Resize(clip1,width*4, height*4, 0.375, 0.375), aSobel().aBlur(), depth=4)
AssumeTFF(clip1)
Interp = nnedi(clip1, field=1)
Deinted=TDeint(clip1,order=1,field=1,type=1,edeint=Interp,emask=TMM(order=1,field=1))
TFM(clip1,mode=6,order=1,PP=7,slow=2,mChroma=true,Clip2=Deinted)
TDecimate(clip1,mode=1)

FastLineDarkenmod(clip2, strength=70,thinning=75)

SetMTMode(3,3)
MSharpen(clip2,threshold=39, strength=40,mask=false, highq=true)
PanoramaWR2(clip2,1024,480, Strength=0.900, AxisShare=0.667) 

SetMTMode(6,3)
aWarp4(Spline36Resize(clip2,width*4, height*4, 0.375, 0.375), aSobel().aBlur(), depth=4)
AssumeTFF(clip2)
Interp = nnedi(clip2, field=1)
Deinted=TDeint(clip2,order=1,field=1,type=1,edeint=Interp,emask=TMM(order=1,field=1))
TFM(clip2,mode=6,order=1,PP=7,slow=2,mChroma=true,Clip2=Deinted)
TDecimate(clip2,mode=1)

main=clip1
pip=clip2

main=bicubicresize(720,480).ConvertToYUY2()
pip=bicubicresize(720,480).Crop(0, 460, 0, 0).ConvertToYUY2()

Layer(main,pip,"add",250,1,460).bicubicresize(720,480)

Last edited by SilSic; 7th August 2015 at 18:12.
SilSic is offline   Reply With Quote
Old 7th August 2015, 18:14   #2  |  Link
sneaker_ger
Registered User
 
Join Date: Dec 2002
Posts: 5,495
You have to put "clip1=" or "clip2=" before almost every line. If you only do e.g. "TDecimate(clip2,mode=1)" it will overwrite the complete clip and everything you have done before is lost. You have to do e.g. "clip2=TDecimate(clip2,mode=1)"
sneaker_ger is offline   Reply With Quote
Old 7th August 2015, 19:16   #3  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 7,211
Perhaps this will work (untested)
Code:
SetMTMode(6,3)
LoadPlugin("C:\Program Files (x86)\AviSynth 2.5\plugins\TUnsharp.dll")
LoadPlugin("D:\plugins\masktools2.dll")
LoadPlugin("D:\plugins\UnFilter.dll")
Import("D:\plugins\FastLineDarken 1.4x MT MOD.avsi")
LoadPlugin("D:\plugins\MSharpen.dll")
Import("D:\plugins\PanoramaWR2.avs")
#########################################

DirectShowSource("Video1.mkv")                              ### ASSIGN to Last, Use implicit Last for this section
                                                            ### NOTE, width*4 and height*4 below are using implicit Last anyway
SetMTMode(6,3)

FastLineDarkenmod(strength=70,thinning=75)

SetMTMode(3,3)
MSharpen(threshold=39, strength=40,mask=false, highq=true)
PanoramaWR2(1024,480, Strength=0.900, AxisShare=0.667) 

SetMTMode(6,3)
aWarp4(Spline36Resize(width*4, height*4, 0.375, 0.375), aSobel().aBlur(), depth=4)
AssumeTFF()
Interp = nnedi(field=1)
Deinted=TDeint(order=1,field=1,type=1,edeint=Interp,emask=TMM(order=1,field=1))
TFM(mode=6,order=1,PP=7,slow=2,mChroma=true,Clip2=Deinted)          ###Dont use Clip2 name, confusing as same as arg name to TFM
TDecimate(mode=1)

#########################################
main = Last                                                         ### why bother with anything else   
#########################################

DirectShowSource("Video2.avi",audio=false).convertfps(29.976)       ##### Same again for clip2

FastLineDarkenmod(strength=70,thinning=75)

SetMTMode(3,3)
MSharpen(threshold=39, strength=40,mask=false, highq=true)
PanoramaWR2(1024,480, Strength=0.900, AxisShare=0.667) 

SetMTMode(6,3)
aWarp4(Spline36Resize(width*4, height*4, 0.375, 0.375), aSobel().aBlur(), depth=4)  ### again requires implicit Last for width etc
AssumeTFF()
Interp = nnedi(field=1)
Deinted=TDeint(order=1,field=1,type=1,edeint=Interp,emask=TMM(order=1,field=1))
TFM(mode=6,order=1,PP=7,slow=2,mChroma=true,Clip2=Deinted)          ### Again, avoid clip2 same as TFM arg name
TDecimate(mode=1)

#########################################
pip = Last                                                         ### why bother with anything else   
#########################################

main=main.bicubicresize(720,480).ConvertToYUY2()
pip=pip.bicubicresize(720,480).Crop(0, 460, 0, 0).ConvertToYUY2()

Layer(main,pip,"add",250,1,460).bicubicresize(720,480)
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???
StainlessS is offline   Reply With Quote
Old 8th August 2015, 12:17   #4  |  Link
SilSic
Registered User
 
Join Date: Aug 2012
Posts: 29
thanks! now it works
SilSic is offline   Reply With Quote
Reply

Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump


All times are GMT +1. The time now is 18:22.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2019, vBulletin Solutions Inc.