I want to upscale a Super Nes video in HD

[StainlessS]

OK, something like this maybe (Just change config stuff to play with it).

LoadPlugin("<path>\PointSize_x64.dll") ## FIX THIS PATH

## ADD SOURCE HERE (RGB32, 256x224)
#AviSource("...")

###   CONFIG   ###
## (256x224 -> 2820x2160)
LQx_ARG  = 4     ## retains some jaggies (best for 'digital' look)
xBRZ_ARG = 4     ## softer gradients (best for 'smooth' look)
SPL_W    = 1024   ## Spline16
SPL_H    = 896
GAU_W    = 5760   # Gauss
GAU_H    = 4320
GAU_PX   = 37.5
GAU_PY   = 12.5
BIC_W    = 2820   # BiCubic (Output)
BIC_H    = 2160
### END CONFIG ###

LQx(LQx_ARG)      # Uncomment 1 or NONE [EDIT: Changed 'Both' to 'NONE']
#xBRZ(xBRZ_ARG)

ConvertToYV12(matrix="Rec709")

## (other filters here -- try QTGMC for example)

#########
Spline16Resize(SPL_W, SPL_H)
nnedi3_rpow2(rfactor=2, nsize=0, nns=2, qual=1, etype=0, pscrn=2, threads=0, opt=0, fapprox=0)
GaussResize2(GAU_W, GAU_H, px=GAU_PX, py=GAU_PY)
BiCubicResize(BIC_W,BIC_H)
return Last

##################################
function GaussResize2(clip C, int target_width, int target_height,
\   float "src_left", float "src_top", float "src_width", float "src_height",
\   float "px", float "py")
{
    px = Default(px, 30.0)
    py = Default(py, px)
    R = C.GaussResize(target_width, C.Height,
    \         src_left, 0, src_width, 0, px)
    \    .GaussResize(target_width, target_height,
    \         0, src_top, 0, src_height, py)
    return R
}

EDIT: changed RED stuff.