replace frame with picture file

[t1dUs]

Since I cannot access avisynt.org then I'll ask it here: what is the function to replace a frame of a clip for a picture file? The thing is that I took one of the frames in my clip and repaired it with paintshop pro. Also, are all the picture formats equally good?

If possible do it with this example in order to see the syntax of the function:
the picture -> c:\picture.bmp
frame to replace -> 300

TIA

[Tripx]

ReplaceFrame

[t1dUs]

thnx Tripx, but isn't there a built in function inside avysinth already? I'd prefer to know that one instead of having to install new dlls in windows' system folder.

PS: I'm gettin external exception E06D7363, so I need somethin else

[Mug Funky]

try this: i haven't used it for a while, but i use this for replacing splats with photoshopped fixes (tedious work...)

function imagesplice (clip c, string "filename", int "frameno")
{
frame=imagesource(filename)
frame=frame.selectevery(frame.framecount,0).assumefps(c.framerate).converttoyv12()
c.trim(0,frameno-1)++frame++c.trim(frameno+1,0)
}

usage:

imagesplice("blurt.png",1200)

would replace frame 1200 with the picture "blurt.png". works for yv12 for now, but it's a trivial matter to modify it for yuy2 or rgb.

just stick that code block in your script, or whack it in a new text file called imagesplice.avsi in your plugins directory.

[foxyshadis]

System folder? You should be putting them in avisynth's plugin folder. You can also add jdl-util.avsi and jdl-range.avsi to the folder instead, and use jdl_replacerange with the same start & end. Something like:

avisource("stuff.avi")
JDL_ReplaceRange(imagesource("picture.bmp").converttoyv12,300,300)

[edit] *shakes fist at Mug Funky*

[t1dUs]

thnx a lot to Mug Funky and foxyshadis, both ways work like a charm , but I think I'll stick to Mug Funky's since it requires less typing :P

[Dogway]

ya, I know the thread is old, but the problem is related to the function posted by Mug Funky.

Im using it in my script together a call function when required loading an avs with all the imagesplice frames list.

Everything works correctly until I put a trim function in the script, which corrupts the framenumber. I would like to know how to make the frame order based on the untrimed video so it keeps consistency.

DirectShowsource("mysource.mp4",audio = false)

trim(1688,1787)

Import("LoadRef.avs")

function imagesplice (clip c, string "filename", int "frameno")
{
frame=imagesource(filename)
frame=frame.selectevery(frame.framecount,0).assumefps(c.framerate).converttoyv12()
c.trim(0,frameno-1)++frame++c.trim(frameno+1,0)
}

LoadRef.avs

imagesplice("1162.jpg",1162)
imagesplice("1347.jpg",1347)
imagesplice("1485.jpg",1485)
imagesplice("1508.jpg",1508)
(...)

[Guest]

Do the trim AFTER the imagesplice's.

[Dogway]

I wished it was that simple. I have tried to put it in every place I could imagine. I dont understand the declaration in the function, but maybe indicating there to read from the original source, and not trimmed version.

[Gavino]

Putting the Trim at the end of the script does make the splices work on the original untrimmed source.

But of course the splices to frames 1162, 1347, 1485 and 1508 will be trimmed out of the final result. Is that what you want?

[Dogway]

ups, sorry. It seemed to be my fault. I took the framenumbers based on ffmpegsource, and after when I changed the call function to DirectShowSource, the framenumbers changed and I didnt realize.

I dont understand why it happens, which of them do you suggest me to use? Sorry for the mistake.

Hola Gavino, me alegro de ver mas españoles por aqui.

[Gavino]

Hola, Dogway.

Originally Posted by Dogway

I took the framenumbers based on ffmpegsource, and after when I changed the call function to DirectShowSource, the framenumbers changed and I didnt realize.
I dont understand why it happens, which of them do you suggest me to use?

DirectShowSource does not always provide frame-accurate seeking, so ffmpegsource is probably better for this source.

[GMJCZP]

Sorry to revive this topic.
A while ago I met the helpful script Mug Funky's ImageSplice, and unfortunately noticed two problems:

- You can't replace the first frame (frame 0)
- Incompatibilities with the audio.

This led me, based on ImageSplice, create gradually a single script to that meets the same idea but in a more functional way...

[GMJCZP]

RescueFrame

The plan in RescueFrame is the following:

- Add to the original video as a first frame the modified frame, that is, as a sort of header record.
- Then, know the frame or frames to replace to use internally the Freezeframe function, by taking the modified frame or "header record".
- Finally, the first frame is removed, all while preserving the original audio, if be present.

Here the script:

###
#
# RescueFrame is a function dedicated for replace undesirable frames
# with frames captured and/or edited previously. For AVS+ only.
#
# Written by GMJCZP
#
# - Initial release (07/11/2014)
#
# - Version 2.0 (24/05/2021)
# Now it works in HBD! (AVS+ only!).
#
# - Version 2.1 (26/05/2021)
# Better handling of Overlay.
#
# - Version 3.0 (06/06/2021)
# Optimization of the entire function, including the elimination of
# Overlay, resulting in a increase in speed; fix in audio handling.
#
###

###
# USAGE / SUGGESTIONS
###
#
# In case of restoration, to capture the frame to edit, making sure that it is
# identical to the original.
# A sure method can be to place this sentence before to call RescueFrame:
# ConverttoRGB24().ImageWriter("", frame, frame, "bmp").ConverttoYV12()
# and then to go to frame. It will be generated a bmp file in the same folder where
# is the Avisynth script. In that instant one already can it erases the sentence of up.
#
# Another sure method is using VirtulDub for Copy frames.
#
# NEVER to use VirtualDubMod for copy/snapshot frames!
#
# Once made the capture can use your favorite program of edition of images
# for its edition and then call this function.
#
###

###
# PARAMETERS
###
#
# "FileName"
# Name of the file of the edited frame. Example: "MyRestoredFrame000.bmp"
#
# "FrameNumber"
# Number of frame to replace.
#
# "NumRep"
# Number of times that the frame will repeat, replacing the successive frames.
#
####

function RescueFrame (clip video, string FileName, int FrameNumber, int "NumRep")
{
   NumRep = Default(NumRep, 0)

	edit_frame = ImageSource(FileName,use_DevIL=true,end=0,fps=framerate(video)).converttoYV12().convertbits(video.BitsPerComponent())
	clp = edit_frame + video.KillAudio()
	clp = clp.Freezeframe(FrameNumber+1,FrameNumber+1+NumRep,0).Deleteframe(0)
	clp = (HasAudio(video) == false) ? clp : AudioDubEx(clp,video)
	return clp
}

EDIT: For some reason I do not know, if StackHorizontal (or StackVertical) is used BEFORE the RescueFrame, the frame to the right (or below) is black, so the call order must be reversed.

[Mounir]

I like this RescueFrame script above but i'd need to work with avisource instead of imagesource (that i've figured it out you only replace source = avisource(FileName) but then come my desire to use a Trim for this avisource to select the wanted frame, here i'm hiting a rock; if you can guide me...

[StainlessS]

Just as in above script, to trim a single frame use

     vFrame = Trim(vClip,FrameNo,-1)

-2 trims 2 frames etc.

Also note, In RescueFrame, FileName and FrameNumber are given as Optional (in quotes) but they do not have defaults and so will
error if called without them.
Either provide defaults or remove quotes.

Also note, FrameSel/Rep can extract any number of frames and then replace them again later.

EDIT: Here:- http://forum.doom9.org/showthread.ph...light=framesel

[GMJCZP]

See post # 14

Currently RescueFrame only operates in 8 bits, the culprit is in the Overlay call, is there any way to bring the script to HBD?

Fortunately it is not a serious matter but academically speaking it would be interesting to resolve it.

[StainlessS]

It would be a better function if supplied as arg, frames clip instead of a filename.
And the clip being required to be in a colorspace compatible with the source clip (and Overlay or Layer).
In AVS+ Overlay/Layer, (I think) colorspace has to be same type, ie Interleaved/Planar, and same bit depth.

This is some code from Work In Progress script to match colorspace exactly. [also some required support functions not posted]

    Function ExL_MatchCS(clip c,clip matchto,String "matrix",Bool "fulls",bool "fulld") { # Match c clip to matchto clip colorspace
        RT_DebugF("ExL_MatchCS: IN c=%s MatchTo=%s",c.X_PixelType,matchto.X_PixelType)
        if(c.X_PixelType != matchto.X_PixelType) {
            # currently (avs+ 3.5) fulld must equal fulls
            mat=Default(matrix,"PC.601") # Matrix default no change ie full range matrix : fulls=auto ie undefined, true for RGB else false.
            matchto.IsYV12?c.ConvertToYV12(matrix=Mat):matchto.IsYUY2?c.ConvertToYUY2(matrix=Mat):matchto.IsRGB24?c.ConvertToRGB24(matrix=Mat)
                \ : matchto.IsRGB32?c.ConvertToRGB32(matrix=Mat):matchto.IsYV16?c.ConvertToYV16(matrix=Mat):matchto.IsYV24?c.ConvertToYV24(matrix=Mat)
                \ : matchto.IsY8?c.ConvertToY8(matrix=Mat):matchto.IsRGB48?c.ConvertToRGB48(matrix=Mat):matchto.IsRGB64?c.ConvertToRGB64(matrix=Mat):Undefined
            if(!Defined) { # Is Avs+ AND MatchTo == Planar, Can use AVS+ functions directly here.
                c
                if(matchto.IsRGB) {
                    matchto.HasAlpha == HasAlpha ? NOP : matchto.HasAlpha ? ConvertToPlanarRGBA(matrix=Mat) : ConvertToPlanarRGB(matrix=Mat)
                } else if(matchto.IsY) {
                    RT_DebugF("Match to IsY")
                    ConvertToY(matrix=Mat)
                } else {
                    RT_DebugF("Match to IsYUVA=%s or ISYUV=%s",matchto.IsYUVA,matchto.IsYUV)
                    if(matchto.Is444)        { ConvertToYUV444(matrix=Mat) }
                    else if(matchto.Is422)   { ConvertToYUV422(matrix=Mat) }
                    else if(matchto.Is420)   { ConvertToYUV420(matrix=Mat) }
                }
                mbpc=matchto.BitsPerComponent  bpc=BitsPerComponent
                if(mbpc!=bpc) {
                    RT_debugF("Converting Bits from %d to %d",X_Bpc,matchto.X_Bpc)
                    ConvertBits(mbpc) #,fulls=fulls,fulld=fulld)
                }
                (matchto.HasAlpha==HasAlpha) ? NOP : HasAlpha ? RemoveAlphaPlane : AddAlphaPlane
            }
        } else { c }
        RT_DebugF("ExL_MatchCS: OUT c=%s matchto=%s",X_PixelType,matchto.X_PixelType)
        return last
    }

It can be a real pain.

Alternative to the orginal mug_funky style function

# NOT HBD aware for FrameSel/FrameRep SHOW=TRUE.
# When Not Showing Text(ie not changing frame content), does not require knowledge of HBD, ie works OK.
Colorbars.ShowFrameNumber.ConvertToYV24.ConvertBits(10).KillAudio
ORG=Last                           # Original, with/without audio
F=FlipVertical                     # Flipped, or maybe from ImageSource
R=F.FrameSel(10,20,30)             # 3 flipped frames, 10, 20, 30, into R clip frames 0,1,2
                                   # Equivalent to 3 frames read from file and converted to same colorspace as source.

Framerep(Last,R, 10,20,30)         # Replace 3 frames, 10, 20, 30 (From R clip frames 0,1,2)

#Framerep(Last,R,SCmd="10;20;30")  # Replace 3 frames 10,20,30, SCMD using command in string. CMD using command File.
AudioDubEx(Last,ORG)               # Restore Audio from source, if present
Info

#convertToRGB32                     # To view. Not needed for some players eg PotPlayer

return Last

EDIT: Above added AudioDubEx

EDIT: FrameSel/FrameRep, does not support Audio, AudioDubEx with original audio from source clip.



EDIT: FrameSel/Framerep supports thousands of frame replacements [commands in text file], timed when plugin first written
to be about 40,000 frames indexes read from text file in about 2 seconds, before frameserving starts.
During frameserving, overhead not much different to a trim and splce of a single frame.

[GMJCZP]

Originally Posted by StainlessS

It would be a better function if supplied as arg, frames clip instead of a filename.
And the clip being required to be in a colorspace compatible with the source clip (and Overlay or Layer).
In AVS+ Overlay/Layer, (I think) colorspace has to be same type, ie Interleaved/Planar, and same bit depth.

This is some code from Work In Progress script to match colorspace exactly. [also some required support functions not posted]

    Function ExL_MatchCS(clip c,clip matchto,String "matrix",Bool "fulls",bool "fulld") { # Match c clip to matchto clip colorspace
        RT_DebugF("ExL_MatchCS: IN c=%s MatchTo=%s",c.X_PixelType,matchto.X_PixelType)
        if(c.X_PixelType != matchto.X_PixelType) {
            # currently (avs+ 3.5) fulld must equal fulls
            mat=Default(matrix,"PC.601") # Matrix default no change ie full range matrix : fulls=auto ie undefined, true for RGB else false.
            matchto.IsYV12?c.ConvertToYV12(matrix=Mat):matchto.IsYUY2?c.ConvertToYUY2(matrix=Mat):matchto.IsRGB24?c.ConvertToRGB24(matrix=Mat)
                \ : matchto.IsRGB32?c.ConvertToRGB32(matrix=Mat):matchto.IsYV16?c.ConvertToYV16(matrix=Mat):matchto.IsYV24?c.ConvertToYV24(matrix=Mat)
                \ : matchto.IsY8?c.ConvertToY8(matrix=Mat):matchto.IsRGB48?c.ConvertToRGB48(matrix=Mat):matchto.IsRGB64?c.ConvertToRGB64(matrix=Mat):Undefined
            if(!Defined) { # Is Avs+ AND MatchTo == Planar, Can use AVS+ functions directly here.
                c
                if(matchto.IsRGB) {
                    matchto.HasAlpha == HasAlpha ? NOP : matchto.HasAlpha ? ConvertToPlanarRGBA(matrix=Mat) : ConvertToPlanarRGB(matrix=Mat)
                } else if(matchto.IsY) {
                    RT_DebugF("Match to IsY")
                    ConvertToY(matrix=Mat)
                } else {
                    RT_DebugF("Match to IsYUVA=%s or ISYUV=%s",matchto.IsYUVA,matchto.IsYUV)
                    if(matchto.Is444)        { ConvertToYUV444(matrix=Mat) }
                    else if(matchto.Is422)   { ConvertToYUV422(matrix=Mat) }
                    else if(matchto.Is420)   { ConvertToYUV420(matrix=Mat) }
                }
                mbpc=matchto.BitsPerComponent  bpc=BitsPerComponent
                if(mbpc!=bpc) {
                    RT_debugF("Converting Bits from %d to %d",X_Bpc,matchto.X_Bpc)
                    ConvertBits(mbpc) #,fulls=fulls,fulld=fulld)
                }
                (matchto.HasAlpha==HasAlpha) ? NOP : HasAlpha ? RemoveAlphaPlane : AddAlphaPlane
            }
        } else { c }
        RT_DebugF("ExL_MatchCS: OUT c=%s matchto=%s",X_PixelType,matchto.X_PixelType)
        return last
    }

It can be a real pain.

Alternative to the orginal mug_funky style function

# NOT HBD aware for FrameSel/FrameRep SHOW=TRUE.
# When Not Showing Text(ie not changing frame content), does not require knowledge of HBD, ie works OK.
Colorbars.ShowFrameNumber.ConvertToYV24.ConvertBits(10).KillAudio
ORG=Last                           # Original, with/without audio
F=FlipVertical                     # Flipped, or maybe from ImageSource
R=F.FrameSel(10,20,30)             # 3 flipped frames, 10, 20, 30, into R clip frames 0,1,2
                                   # Equivalent to 3 frames read from file and converted to same colorspace as source.

Framerep(Last,R, 10,20,30)         # Replace 3 frames, 10, 20, 30 (From R clip frames 0,1,2)

#Framerep(Last,R,SCmd="10;20;30")  # Replace 3 frames 10,20,30, SCMD using command in string. CMD using command File.
AudioDubEx(Last,ORG)               # Restore Audio from source, if present
Info

#convertToRGB32                     # To view. Not needed for some players eg PotPlayer

return Last

EDIT: Above added AudioDubEx

EDIT: FrameSel/FrameRep, does not support Audio, AudioDubEx with original audio from source clip.

I have already mentioned this to you before, it is difficult for me to follow up on certain issues. Thanks.

The filename thing is because ImageSource needs the image file, which is the one that will replace the frame or group of frames.

The error message says:

"Overlay: input and overlay clip must have the same bit depths!"

[StainlessS]

Well as I said, the function is not very well defined/implemented.
Scrap it and re-write taking clip arg instead of filename. Unless you want to implement
additional code which auto converts to same colorspace as source.
It is a lot easier for the user to just do a convert than to auto convert.
I'm not really quite sure what the requirements are, both have to be interleaved, or both planar,
and same bit depth, may be the minimum requirements for Overlay and Layer.

EDIT: Also may need to use eg Conversion Matrix.

EDIT: I think Overlay did originally work with any colorspace [pre AVS+],
but currently needs same bit depth and same interleaved/planar format,
so not going be an easy drop-in fix for your function.