MPC-HC Project Manager
Join Date: Mar 2007
Posts: 2,317
|
Deblock_qed_mt2 wiki link does not work, i cannot find the filter in google (they all point to the non working wiki)
I now have the following files
fft3dgpu_20060614.zip
frfun7_rev6.zip
gradfun2db_25_dll_20060315.zip
mvtools_25_dll_20060605.zip
ttempsmooth_25_dll_20051117.zip
tweakcolor_25_dll_20040412.zip
Avisynth_257.exe
megui-0.2.5.1007.exe
GrainOptimizer 2.01.zip
I found some newer versions though (not sure if this will break the script you posted?)
fft3dgpu0.8.2.7z
megui-0.2.6.1034.exe
That audio fix part does not require any extra plugins right?
Can i just cut and paste that to source like this:
Code:
# source
video=DGDecode_mpeg2source("C:\meGUI\SG1\SG1.d2v") #video
audio=nicac3source("SG1 T01 2_0ch 224Kbps DELAY -128ms.ac3",2) #audio
audiodub(video,audio) # composite audio/video stream
delayaudio(-0.128) # adjust sync like DGIndex told us to in filename
assumefps(24,1,true) # redefine video as 24fps and audio as 46080Hz, slowing both to be correct
ssrc(48000,false) # resample audio to 48KHz for hardware compatibility
# deinterlace if needed
#TV (16..235) -> PC (0..255) levels. Much better blocking and banding in encode but your display must be adjusted for the different brightness/contrast to source DVD.
Tweak(bright=-16, cont=1.164, coring=false)
#deblock before any denoise/crop/resize to give deblocker a clean shot
DeBlock_QED_mt2( quant1=20, quant2=24, aOff1=2, bOff1=4, aOff2=4, bOff2=8 )
#crop black borders
crop(2,4,-6,-8) #or whatever
#resize up to next multiple of 16 for encoder efficiency and compatibility with GradFunkMirror() later
spline36resize ( 16*((width+15)/16), 16*((height+15)/16) )
#Denoise or grainoptimizer to taste
#grainoptimizer()
#FrFun7(1.1,2.5,1.5) #fractal spatial denoiser
#TTempSmooth(maxr=5) #pure temporal
#fft3dgpu(sigma=1,bh=32,bw=32,bt=4,precision=2,plane=4) #fast spatio-temporal, bw/bh=32 avoids occasional colour glitches
mvdegrain2p (source=last,blksize=16,overlap=8,sharp=2,thSAD=400,idx=1) #mocomped temporal, the daddy
#sharpen if you want (not my thing, ask somebody else)
#Tackle banding in flat areas
GradFunkMirror(1.2)
function MVDegrain2p(clip "source", int "blksize", int "overlap", int "sharp", int "thSAD", int "idx")
{
blksize=default(blksize,8) # blksize value (4, 8 or 16)
overlap=default(overlap,blksize/2) # overlap value (0 to half blksize)
sharp=default(sharp,1) #
thSAD=default(thSAD,400) # higher risks ghosting, lower risks "staggered denoising"
idx=default(idx,1) # use various idx for different sources in same script
backward_vec2 = source.MVAnalyse(isb = true, delta = 2, pel = 2, blksize=blksize, overlap=overlap, sharp=sharp, idx = idx)
backward_vec1 = source.MVAnalyse(isb = true, delta = 1, pel = 2, blksize=blksize, overlap=overlap, sharp=sharp, idx = idx)
forward_vec1 = source.MVAnalyse(isb = false, delta = 1, pel = 2, blksize=blksize, overlap=overlap, sharp=sharp, idx = idx)
forward_vec2 = source.MVAnalyse(isb = false, delta = 2, pel = 2, blksize=blksize, overlap=overlap, sharp=sharp, idx = idx)
source.MVDegrain2(backward_vec1,forward_vec1,backward_vec2,forward_vec2,thSAD=thSAD,idx=idx)
}
Function GradFunkMirror( clip c, float "strength" )
{
#counters edge effects for gradfun2db()
#gradfun2db() requires width mod8 and height mod2
strength = default( strength, 1.2 )
w = c.width()
h = c.height()
vflip = c.FlipVertical()
hflip = c.FlipHorizontal()
stackhorizontal( hflip.crop( w-16, 0, 16, h ).addborders( 0, 16, 0, 16 ),
\ stackvertical( vflip.crop( 0, h-16, w, 16 ), c, vflip.crop(0, 0, w, 16 ) ),
\ hflip.crop( 0, 0, 16, h ).addborders( 0, 16, 0, 16 ) )
gradfun2db( strength )
crop( 16, 16, -16, -16 )
Return last
}
Last edited by tetsuo55; 31st October 2007 at 15:10.
|