Audio Encoding Drag and Drop onto shortcut?

[ArcticFox]

Hi i was wondering if it was at all possible to create a shortcut with all the options set up for faac so i dont have to keep typing out the same command, i can just drag and drop my audio file into and it will automatically encode?

Thanks

[johnman]

If i wanted to do something like you describe i would make a batchfile which calls faac.exe with the correct settings and the dropped filename. I cant give you more details since im not entierly sure how to do this, but i think it might be worth a try.

(EDIT, to be honest..... what i really would do is support faac in wavewizard instead of making a batch file ;) )

[tebasuna51]

Try with this file faac.vbs:

' Faac.vbs Put this file in the same folder than faac.exe
' Make a link to this file in the desktop
' Drag & drop wav files over the desktop link
Dim title, msg1, wsh, args, prgfull, fso, msg, i, oExec, outfile
title = WScript.ScriptName: title = left(title, len(title) - 4)
msg1 = title & " encode wav's to aac." '**
' Verify arguments
Set wsh = WScript.CreateObject("WScript.Shell")
Set args = WScript.Arguments
If args.Count = 0 Then
MsgBox msg1 & vbCR & "Use drag & drop to specify input files.", vbInformation, title
WScript.Quit
End If
' Search for title.exe in the same folder than title.vbs
prgfull = WScript.ScriptFullName
prgfull = left(prgfull, len(prgfull) - len(WScript.ScriptName)) & title & ".exe"
Set fso = CreateObject("Scripting.FileSystemObject")
If Not fso.FileExists(prgfull) Then
MsgBox "Don't found " & prgfull, vbCritical, title
WScript.Quit
End If
' Process the files
For i = 0 To args.Count-1
if LCase(Right(args(i), 4)) = ".wav" then ' verify extension
outfile = left(args(i), len(args(i)) - 3) & "aac" ' Or mp4, m4a
msg = prgfull & " -q 100 -o " & outfile & " " & args(i) ' Your parameters
oExec = Wsh.Run(msg, 1, True)
end If
Next
WScript.Quit