Deinterlacing video exported from Premiere Pro

[Mistar Muffin]

Hey guys, I'm working on a school project where I've put together scenes from various movies that I captured from VHS tapes. Anyways, I exported my final cut using HuffYUV 2.1.1, 640x480 and 1.0 pixel aspect ratio. Now, I set it to No Fields (Progressive) in the options, but when I exported some of my scenes are still interlaced. I didn't really care because I still had to encode it to XviD RC4 while using avisynth to crop off some slight tracking noise along the bottom of the video, so I figured I'd deinterlace in my script. When deinterlacing using FieldDeinterlace, edges of things look jagged, like a game without antialiasing. So I'd like to know:

A) What deinterlace filter do I need to use since I set No Fields (Progessive) in Premiere so that I wont have jaggy edges....

OR

B) Will setting Premiere to Upper or Lower field allow me to use FieldDeinterlace without jaggies?

(This is Premiere Pro)

TIA.

[Mug Funky]

you'll get jaggies whenever you use a simple deinterlacer. if you're not going to re-export, then i suggest using Tomsmocomp or Sangnom in avisynth (it's a matter of preference really, but i prefer tomsmocomp in 75% of cases. sangnom behaves badly on concave corners, like mouth and eye corners)

i've got a nice full-rate deinterlacer (bobber), but i haven't modded it for simple deinterlacing, which is preferable as it'll be wasted frames otherwise.

will post it once i've modded it.

[edit]

quicker than i thought...

you need tomsmocomp, kerneldeint and sangnom to run this. if you can't be bothered installing one of these, simply remove the offending statement below :)

best way to use something like this is to place it in a text file, save as "maskDeint.avsi" and put in your plugins folder.


function maskDeint (clip c, int "order", int "cut", int "rolloff", bool "post",
\ bool "halfy", int "bobber")
{
order=default(order,0)
cut=default(cut,1)
rolloff=default(rolloff,16)
rolloff=cut+rolloff
post=default(post,false)
halfy = default(halfy,true)
bobber = default(bobber,1)

c2 = (halfy==true)? c.horizontalreduceby2() : c
c_toms = c.tomsmocomp(order,5,0)
c_sang = c.sangnom(order)
c_kern = c.kerneldeint(order=order, threshold=0)
cdeint = (bobber==1)? c_kern : (bobber==2)? c_sang : c_toms

cdeint = (post==true)?
\cdeint.yv12convolution(horizontal="1",vertical="1,2,1",Y=3,U=3,V=3,usemmx=true) : cdeint
overlay(c,cdeint,mask=mcComb(c2,cut,rolloff).pointresize(c.width,c.height))
}

##### misc functions called inside the above #####

function McComb (clip c, int "cut", int "rolloff")
{
cut=default(cut,1)
rolloff=default(rolloff,cut+16)
c=c.converttoyv12(interlaced=true)
overlay(c.doubleweave().selectodd(),c,mode="difference").limiter()
yv12convolution(horizontal="1",vertical="1,-2,1",Y=3,U=0,V=0,usemmx=true)
gauss(8).levels(cut,1,rolloff,0,255,coring=false)
}

function gauss (clip c,int "radius",bool "conv",int "precision") {

radius=default(radius,4)
conv=default(conv,false)
precision=default(precision,8)
mul=int(pow(2,precision))

Function siney(string s,int stop,int len,int mul)
{
eqn = string(round(mul*pow(sin(pi*stop/len),2)))
#(stop == 0) ? s : eqn + "," + siney(s,stop-1,len)
return (stop == 0) ? s : siney(s,stop-1,len,mul) + "," + eqn
}

matrix=siney("",radius*2,radius*2,mul)
matrix=matrix.midstr(2,(matrix.strlen()-3))

(conv==false)?c.bilinearresize(4*(c.width/(radius*2)),4*(c.height/(radius*2)))
\.bicubicresize(c.width,c.height,1,0):
\c.yv12convolution(horizontal=matrix,vertical=matrix,Y=3,U=3,V=3,usemmx=true)

}



defaults will do fine...

general use:

maskDeint()

parameters:

order = 0 or 1, for BFF or TFF

cut = leave this as it is unless there's lots of shimmer (not likely, but possible on noisy-as-hell video)

rolloff = blending between deinterlaced and regular - this is the better one to modify for noisy clips.

post = true/false. if you get combs left over, set this to true (again, not likely but possible, especially if you play with cut and rolloff).

this is tuned so defaults work for 1-chip DV PAL footage... but i've never needed to modify it for other sources.


[edit]

oops... forgot i used other functions in this...

[Mistar Muffin]

I tried TomsMoComp before I posted, and it seemed to remove the jaggies but in its ReadMe it says to not use it on mixed materials. In my video, I have DVD sources, some of which are FILM, some of which aren't, along with DV captures of VHS tapes....so I'll use Tom's by itself as long as it won't mess up NONinterlaced material in my video (like the dvds, for some reason they arent interlaced, only certain sources are......can I use Tom's for the whole video which contains mixed types?)