Is this aliasing?? interlace?? How to remove it..

[wlsk3981]

Hi.

I have an NTSC Hybrid DVD source that has some strange distortion

I can't seem to get rid of. How to remove it??

http://i229.photobucket.com/albums/ee269/wlsk3981/vob_01.jpg

http://i229.photobucket.com/albums/ee269/wlsk3981/vob_02.jpg

http://i229.photobucket.com/albums/ee269/wlsk3981/vob_03.jpg

http://i229.photobucket.com/albums/ee269/wlsk3981/vob_04.jpg

http://i229.photobucket.com/albums/ee269/wlsk3981/vob_05.jpg


mpeg2source("FullMetal2nd.d2v")
AssumeTFF()
mvbob().BlendBob()
SAA()



Here is an unprocessed clip (vob.rar / 7.65M)

http://bigmail31.mail.daum.net/Mail-bin/bigfile_down?uid=3-UOtx9SlQzwTrs2wnrxqieaMEfH7.mI

or

http://www.wikiupload.com/download_page.php?id=27107




P.S. Sorry, I can't speak english very well

[Sagekilla]

This is a interlaced DVD? Correct me if I'm wrong, but if it is it looks to be aliasing from mvbob.

[cacepi]

This is a interlaced DVD? Correct me if I'm wrong, but if it is it looks to be aliasing from mvbob.
It looks to be a little of both. The first vob definitely looks like aliasing, but the others are probably due to this being a hybrid DVD with an irregular interlace pattern. It's especially evident in the 3rd vob, which has a number of consecutive interlaced frames.

The best way to approach this is, in my opinion, Tritcal's tivtc filter set (http://forum.doom9.org/showthread.php?t=82264). Note that you'll have to read up on how to deal with hybrid video (http://avisynth.org/mediawiki/VFR). Long story short: you'll have to be familiar with overriding TFM's pattern matching. It'll take a while to pinpoint each error, but most of them can be fixed.

Good luck!

[TheRyuu]

Try this:
mpeg2source("FullMetal2nd.d2v",info=3)
AssumeTFF()
tfm(d2v="FullMetal2nd.d2v").tdecimate()
colormatrix(hints=true) #I believe this source needs colormatrix.
antialiasing(hqedge=true)

I feel that SAA blurs the image too much. Plus, it's a DVD source so AA really shouldn't be needed in the amount SAA provides (I could be wrong though, I've seen bad DVD sources :P)

Almost all american anime needs IVTC, not bobbing (I have not yet looked at the clip, I will soon though :)). So, try that tfm/tdecimate script above and see how it works out. colormatrix is just there incase the colorspace needs a conversion.

After getting it deinterlaced, think about denoising/sharpening it with something like fft3dfilter and limitedsharpenfaster.

Edit:
After looking at your clip, you should not be using mvbob. My script above works fine on it. There was some aliasing after the deinterlacing but it was only very subtle and was quickly fixed after the call to antialiasing.

function antialiasing( clip orig, int "th_luma", int "th_croma", string "type", int "order", int "aath", bool "HQedge")
{

# "th_luma" and "th_croma" affect directly the edge detection: higher values = more edges filtered
# set "order = 0" for Top Field First; order = 1 --> Bottom Field First
# aath = anti-aliasing strenght (default should be fine)


th_luma = Default(th_luma, 20)
th_croma = Default(th_croma, 20)
type = Default(type, "sobel")
order = Default(order, 1)
aath = Default(aath, 48)
HQedge = Default(HQedge, false)
ox = orig.width
oy = orig.height
dx = orig.width * 2
dy = orig.height * 2

orig.convertToYV12()
a=last
b=lanczos4Resize(dx, dy).TurnLeft().SangNom(order,aath).TurnRight().SangNom(order,aath)

# native chroma edges:
#c=b.lanczosresize(ox,oy).EdgeMask(0, th_luma, 0, th_croma, type,Y=3,U=3,V=3)

# use luma edges for chroma:
c=b.lanczosresize(ox,oy).EdgeMask(0, th_luma, 0, th_croma, type,Y=3,U=1,V=1).FitY2UV()

d= logic( b.DEdgeMask(0,255,0,255,"5 10 5 0 0 0 -5 -10 -5", divisor=4,Y=3,U=1,V=1)
\ ,b.DEdgeMask(0,255,0,255,"5 0 -5 10 0 -10 5 0 -5", divisor=4,Y=3,U=1,V=1)
\ ,"max").greyscale.levels(0,0.8,128,0,255,false).FitY2UV().lanczosresize(ox,oy)
b=b.lanczosresize(ox,oy)

HQedge ? MaskedMerge(a,b,d,Y=3,U=3,V=3) : MaskedMerge(a,b,c,Y=3,U=3,V=3)
}

[DarkT]

Long story short: you'll have to be familiar with overriding TFM's pattern matching. It'll take a while to pinpoint each error, but most of them can be fixed.

Good luck!


Yup, those are the fumoffu dvd9 from adc, eh? I had to work with dvd5, and I had similiar problems, and it was all easily solved with TFM's overrides file... Easily, as in "simple, but not easy" - because it takes frame by frame looking and writing down etc... YATTA could help with that, I heared... But I trusted manual + .txt file more... Dunno...

I intend to get those sweet dvd9's myself too some time...