Help with color artifacts...

[spyOne]

Hi,

Here is an image of what i called "color artifacts"

http://maxupload.com/img/6D9D10BA.png

Is there any "magic" script to correct that?

I was adviced to denoise chroma a lot using this:
FFT3DFilter(sigma=8,bt=5,plane=3)

here it is the result

http://img295.imageshack.us/img295/8348/01pm2.png

Can i improve this?

Vob sample if u need:
http://rapidshare.com/files/55264942/vobsample.vob

And by the way, this is pal interlaced source, any tips to deinterlace?

Thx in advance

[Boulder]

Post your complete script. You may need to tweak the four different sigma parameters if you wish to avoid destroying the chroma while removing the rainbowing.

I must admit, Fawlty Towers is a tough one.

[spyOne]

mpeg2source("D:\Fawlty Towers\EP.1\ep1.d2v",info=3)
ColorMatrix(interlaced=true)
KernelDeInt(order=1,sharp=true)
FFT3DFilter(sigma=8,bt=5,plane=3)

and only crop and resing after this.

thx

[Serbianboss]

It looks like rainbow:

http://forum.doom9.org/showthread.php?t=115467&highlight=derainbow

[spyOne]

It looks like rainbow:

http://forum.doom9.org/showthread.php?t=115467&highlight=derainbow

used this:

you might try this to diminish rainbows:

loadplugin("dgdecode.dll")
loadplugin("BiFrost.dll")
Loadplugin("Mipsmooth.dll")
Loadplugin("MSharpen.dll")
Loadplugin("MaskTools-1.5.6.dll")

Import("DeRainbow2.avsi")

mpeg2source("avatar.d2v")

BiFrost(interlaced=true,scenelumathresh=1.5,variation=2)

DeRainbow2(8)


==

I modified Derainbow2 in order to limit bleeding of red: blur
set to 1.47 rather than 1.58

I capture analog at 640x480; perhaps that's the difference.
Even so, the above seems to be effective.

..

DeRainbow2

# === by Lothar
#
# Requires MaskTools 1.5.6, MSharpen, Mipsmooth
#

function DeRainbow2(clip org, int "thresh")
{

#Based on DeRainbow by Sh0dan

assert(org.isYV12(),"DeRainbow2() requires YV12 input!")
thresh = default(thresh, 10)

org_u = utoy(org)
org_v = vtoy(org)

msharpen(org, threshold = thresh, mask=true)
reduceby2()
greyscale()
uv = blur(1.5).levels(0,2.0,255,0,255, coring=false).levels(50,2.0,255,0,255, coring=false)

filtered_u = org_u.mipsmooth(spatial=255, temporal=255, scenechange=3, show=false, method="strong", scalefactor=0.5)

filtered_v = org_v.mipsmooth(spatial=255, temporal=255, scenechange=3, show=false, method="strong", scalefactor=0.5)


u_final = MaskedMerge(org_u, filtered_u, uv)
v_final = MaskedMerge(org_v, filtered_v, uv)

derainbowed = ytouv(u_final, v_final, org)

#edgem = org.Edgemask(type = "cartoon", thy1=6 , thy2=6, thc1=6, thc2=6).expand().blur(1.58).FitY2UV()
edgem = org.Edgemask(type = "cartoon", thy1=6 , thy2=6, thc1=6, thc2=6).expand().blur(1.47).FitY2UV()

return MaskedMerge(org, derainbowed, edgem, Y=1, U=3, V=3)

}
#

..

Seemed to work.



It worked just perfect...

Here is a sample:

http://maxupload.com/img/7FD052FE.png

Thx for ur time and help.

:thanks: